converting csv file to rdf using tarql shows empty results - csv

Question

I m using tarql to convert a csv file to rdf the command runs correctly but i can't find the output (nothing is shown in the windows cmd line and no file is generated)
I m using tarql with windows with the following cmd
C:\tarql-master\target\appassembler\bin\tarql.bat --ntriples xx.rq xx.csv
here is my code
PREFIX dc: <http://dcontology/a#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
CONSTRUCT {
?URI owl:class dc:dataset;
dc:identifier ?identifier;
dc:title ?title;
dc:description ?description;
dc:category ?category;
dc:keywords ?keywords;
dc:PublicationDate ?PublicationDate;
dc:UpdateDate ?UpdateDate;
dc:frequencyofupdate ?frequencyofupdate;
dc:Format ?Format;
dc:License ?license
}
FROM <file:Metabase.csv>
WHERE {
BIND (URI(CONCAT('http://dcontology/dataset/', ?identifier)) AS ?URI)
BIND (xsd:integer(?identifier) AS ?identifier)
BIND (xsd:string(?title) AS ?title)
BIND (xsd:string(?description) AS ?description)
BIND (xsd:string(?category) AS ?category)
BIND (xsd:string(?keywords) AS ?keywords)
BIND (xsd:string(?PublicationDate) AS ?PublicationDate)
BIND (xsd:string(?UpdateDate) AS ?UpdateDate)
BIND (xsd:string(?FrequencyOfUpdate) AS ?FrequencyOfUpdate)
BIND (xsd:string(?format) AS ?format)
BIND (xsd:string(?license) AS ?license)
}`
and here is the csv file header`enter image description here

Answer 1

Case sensitivity
The matching of CSV column names and SPARQL variables is case-sensitive.
As you have, for example, "Description" as CSV column name, you need ?Description in the WHERE block of your SPARQL query.
PREFIX dc: <http://dcontology/a#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX owl: <http://owlontology/a#> # see bottom of this answer
CONSTRUCT {
?URI
owl:class dc:dataset ;
dc:identifier ?identifier_int ;
dc:title ?title_str ;
dc:description ?description_str ;
dc:category ?category_str ;
dc:keywords ?keywords_str ;
dc:PublicationDate ?publicationDate_str ;
dc:UpdateDate ?updateDate_str ;
dc:frequencyofupdate ?frequencyOfUpdate_str ;
dc:Format ?format_str ;
dc:License ?license_str .
}
#FROM <file:Metabase.csv>
WHERE {
BIND ( URI(CONCAT( 'http://dcontology/dataset/', ?Identifier )) AS ?URI ) .
BIND ( xsd:integer(?Identifier) AS ?identifier_int ) .
BIND ( xsd:string(?Title) AS ?title_str ) .
BIND ( xsd:string(?Description) AS ?description_str ) .
BIND ( xsd:string(?Category) AS ?category_str ) .
BIND ( xsd:string(?Keywords) AS ?keywords_str ) .
BIND ( xsd:string(?PublicationDate) AS ?publicationDate_str ) .
BIND ( xsd:string(?UpdateDate) AS ?updateDate_str ) .
BIND ( xsd:string(?FrequencyOfUpdate) AS ?frequencyOfUpdate_str ) .
BIND ( xsd:string(?Format) AS ?format_str ) .
BIND ( xsd:string(?License) AS ?license_str ) .
}
Error
If tarql doesn’t find anything to convert (e.g., because the correct column names are not included in the query), it gives no output instead of an error.
Your query, however, should give an error, because you don’t have the owl prefix defined:
Error parsing SPARQL query: Line 5, column 8: Unresolved prefixed name: owl:class
Vocabularies
If you meant to use the OWL ontology, note that there is no owl:class property defined. If you want to say that the ?URI entity belongs to a class, you can use the rdf:type property (or shorthand: a).
dc is the common prefix for DCMI Metadata Terms, which doesn’t define dc:category, dc:keywords, dc:PublicationDate, dc:UpdateDate, or dc:frequencyofupdate.
dc:Format and dc:License only exist as lowercase variants, and dc:dataset only exists as uppercase variant (by convention, lowercase terms refer to properties, and uppercase terms refer to classes).
In case you don’t use the DCMI Metadata Terms vocabulary, it’s a good practice to use a different prefix than dc, because it’s such a well-known vocabulary/prefix.