Tcl OO method 'new' failing to override - tcl

Question

Why does the 'new' method not seem to allow overriding in Tcl OO?
% oo::class create A {
method new {} { puts "In A's new"; return [next] }
}
::A
% A new
::oo::Obj15
% A new
::oo::Obj16
% info class definition A new
{} { puts "In A's new"; return [next] }
% info class call A new
{method new ::A method}
A's new method exists, but doesn't seem to get called when "A new" is executed.
Can anyone explain what's happening here?

Answer 1

The methods you define in a class can be invoked on an instance of the class:
% oo::class create A {
method new {} { puts "In A's new"; return [next] }
}
::A
% set obj [A new]
::oo::Obj12
% $obj new
In A's new
no next method implementation
If you want to augment the new method of class A, use self:
% oo::class create A {
self method new {} { puts "In A's new"; return [next] }
}
::A
% A new
In A's new
::oo::Obj12

Answer 2

As documented at http://www.tcl-lang.org/man/tcl8.6/TclCmd/class.htm#M10, MyClass new calls the class constructor not a method named "new".
You want
oo::class create A {
constructor {} { puts "In A's new"; return [next] }
}

Answer 3

When you do $obj $mth, the $mth method is looked up on the $obj object, with all its contributions from the class hierarchy. In the case of A new, the object is the class A, and the method is called new, that has an implementation supplied by oo::class (which makes the object structures, allocates a name, calls the constructors with the arguments you gave, and returns the fully-qualified name).
You can intercept that by defining a new method on A itself, or by mixing in a suitable class into the object, or by using a metaclass. (All of those will want to use next to delegate actual construction to the standard method.)
Scheme 1: object method on class object
oo::class create A {
self method new {} { puts "In A's new"; return [next] }
}
# Variant of scheme 1; syntactically different, makes same thing
oo::class create A
oo::objdefine A {
method new {} { puts "In A's new"; return [next] }
}
Scheme 2: mixin into class object
oo::class create B {
method new {} { puts "In [self]'s new"; return [next] }
}
oo::class create A {
self mixin B
}
Scheme 3: metaclass
(Metaclasses are just classes that subclass oo::class itself.)
oo::class create C {
superclass oo::class
method new {} { puts "In [self]'s new"; return [next] }
}
C create A {
# any other method definitions you want here
}
Metaclasses are definitely the best option when you want to make whole families of these things, and mixins allow for a more targeted approach. (Yes, the capabilities overlap.)