Extract values of Set-Cookie headers from string in TCL - tcl

Question

I am making a sideband connection in F5 Big-IP and getting the response headers as a utf-8 string
I want to extract the value of the cookies from a string like:
"Set-Cookie {__aaaa=724131337970; HttpOnly; path=/; Expires=Sun, 27-Nov-22 06:43:44 GMT ; Max-Age=15724800; SameSite=Lax} Set-Cookie {__bbbb=1653806624; HttpOnly; path=/; Expires=Sun, 27-Nov-22 06:43:44 GMT ; Max-Age=15724800; SameSite=Lax} Set-Cookie {__ccc=1653806624; HttpOnly; path=/; Expires=Sun, 27-Nov-22 06:43:44 GMT ; Max-Age=15724800; SameSite=Lax}"
I need to comeup with a proc to extract the value of the cookies from "_aaa=..." to the end of its value and the proc shoud get all the cookie values no matter if there is two cookies or three cookies or even more
in the end I need to have a list of those cookies like:
{ {__aaaa=724131337970; HttpOnly; path=/; Expires=Sun, 27-Nov-22 06:43:44 GMT ; Max-Age=15724800; SameSite=Lax} {__bbbb=1653806624; HttpOnly; path=/; Expires=Sun, 27-Nov-22 06:43:44 GMT ; Max-Age=15724800; SameSite=Lax} {__ccc=1653806624; HttpOnly; path=/; Expires=Sun, 27-Nov-22 06:43:44 GMT ; Max-Age=15724800; SameSite=Lax} }
What is the best way to do it? using string range, findstr or using regexp?

Answer 1

That input descriptor looks a lot like a list where every second item is the content of a Set-Cookie header. The spec for handling cookies is complicated and what you see in practice are not exactly the things that the RFC describes. (I wrote Tcl 8.7's cookie support; I looked at this in some depth.)
The header is a semicolon-separated list where the first item is the cookie name and value, and subsequent parts are options (all of those are key/value with = separating the two). The key option you might care about here is the Expires header, which is absent in session cookies, present and in the future for persistent cookies, and present and in the past to delete a cookie. (That last part is not documented anywhere!) However, handling that gets really complicated — there isn't a consistent workable standard for what the format of the date is, and then you've got to do additional work to handle storage and so on — that I'll omit it here.
# Much much easier to do some of this work in a procedure
proc parseCookieHeader {header} {
set pieces [split $header ";"]
if {![regexp {^([^=]+)=(.*)$} [lindex $pieces 0] -> key value]} {
error "malformed Set-Cookie header"
}
# Cookie option parsing, at least at a basic level
set options {}
foreach option [lrange $pieces 1 end] {
if {[regexp {^([^=]+)=(.*)$} $option -> k v]} {
dict set options [string tolower [string trim $k]] [string trim $v]
}
}
return [list [string trim $key] [string trim $value] $options]
}
foreach {a b} $input { # $input is the string you started with
# Drop the options for simplicity
lassign [parseCookieHeader $b] key value
# Store them all in an array; the order shouldn't matter
set cookies($key) $value
}
parray cookies
# cookies(__aaaa) = 724131337970
# cookies(__bbbb) = 1653806624
# cookies(__ccc) = 1653806624
If you have multiple cookies with the same name, the last one wins. This is how it works with real sites too, and is another part of why handling cookies is really messy. (The code also assumes it doesn't have to do any complex policy enforcement such as limiting what paths or hosts they apply to.)