A few value convert to CSV Mulesoft - csv

Question

%dw 2.0
output application/csv quoteValues=true, separator=";", header=true
---
[
{
Aaa: payload.problem.Aaa[0],
Bbb: payload.problem.Bbb[0]
}
]
And this write it to CSV like this:
Aaa;Bbb
1234; Test1
But this payload looks like this:
"problem": {
"Aaa": [
"1234",
"1567",
"105"
],
"Bbb": [
"Test1",
"Test2",
"Test3"
]
}
And I would like to write all 3 value or more depends from my request to my CSV. But now I can do it only if I specify which element from the array (example payload.issues.Aaa[0]). Because under my key Aaa I don't know exactly how many value I will get to response.

Answer 1

This solution assumes that the data for the first column has the same number of rows as all the others.
First I capture the names of columns from the key names in payload.problem, using the function namesOf(), and store the array of names in the variable column.
Then I map over the first 'column' to get the index of each row. Using that index I iterate over each column name obtaining the value for that column at that index, and transforming it into a key-value (column name, value of that column for the row). Finally I use reduce() to concatenate all the key-values from the same row into a single object, which represents the row as DataWeave expects to transform to CSV. If you change the output type to JSON you will see the structure more clearly.
%dw 2.0
output application/csv quoteValues=true, separator=";", header=true
var columns=namesOf(payload.problem)
---
payload.problem[columns[0]] map ((item, index) -> (
columns map ($): payload.problem[$][index])
reduce ($$++$)
)
Output:
Aaa;Bbb
"1234";"Test1"
"1567";"Test2"
"105";"Test3"
If the columns are not of the same size you can use this alternative that will find first a column with the maximum length and use it as the first iteration:
%dw 2.0
output application/csv quoteValues=true, separator=";", header=true
import firstWith from dw::core::Arrays
var columns=namesOf(payload.problem)
var maxColumnSize=max(columns map sizeOf(payload.problem[$]))
var maxColumnName=columns firstWith (sizeOf(payload.problem[$]) == maxColumnSize)
---
payload.problem[maxColumnName]
map ((item, index) -> (
columns map ($): payload.problem[$][index])
reduce ($$++$)
)