Finding webpage elements to print on excel spreadsheet using VBA - html

Question

Edit1: Solutions to my questions can be found in the comments below, regards to Zwenn
I need help with finding the right website elements to use in the instruction when printing in excel. The following is what I have which works when printing the first half of the page, but not the second. I'm not able to print the "all seasons course statistics" table featured on the webpage using the navigation below and I would like to be able to do so using different element navigation.
When looking for the "all seasons course statistics" table on the webpage, the table elements are past the "tabs-wrapper rns-scroll" class-element when inspecting the webpage.
Website in question: https://www.racingandsports.com/thoroughbred/jockey/jake-bayliss/27461.
The first part of the VBA code:
Sub Horse2()
Dim IE As InternetExplorer
Application.ScreenUpdating = False
Set IE = New InternetExplorer
IE.Visible = True
Set ws = ThisWorkbook.Worksheets("Sheet1")
Dim http As New XMLHTTP60, html As New HTMLDocument
Dim node As HTMLHtmlElement
Dim nodeTr As HTMLHtmlElement
Dim nodeDiv As HTMLHtmlElement
Dim Element1 As HTMLHtmlElement
Dim node1 As HTMLHtmlElement
Dim currentUrl As String
With http
.Open "GET", "https://www.racingandsports.com/thoroughbred/jockey/jake-bayliss/27461", False
.send
html.body.innerHTML = .responseText
End With
The element navigation starts here in the VBA. The elements here just navigate through other tables rather than the one I need and I have no idea how to get it to go to the "all seasons course statistics" table, even when it contains the same element names.
With html.getElementsByClassName("col-md-12 table-responsive")
For Each node In html.getElementsByClassName("table rns-table")
r = r + 1: c = 4
For Each nodeTr In node.getElementsByTagName("tr")
With nodeTr.getElementsByTagName("td")
If .Length Then
ws.Cells(r + 1, c + 3) = .Item(0).innerText
On Error Resume Next
ws.Cells(r + 1, c + 4) = .Item(1).innerText
On Error Resume Next
ws.Cells(r + 1, c + 5) = .Item(2).innerText
On Error Resume Next
ws.Cells(r + 1, c + 6) = .Item(3).innerText
On Error Resume Next
ws.Cells(r + 1, c + 7) = .Item(4).innerText
On Error Resume Next
ws.Cells(r + 1, c + 8) = .Item(5).innerText
On Error Resume Next
ws.Cells(r + 1, c + 9) = .Item(6).innerText
On Error Resume Next
ws.Cells(r + 1, c + 10) = .Item(7).innerText
On Error Resume Next
ws.Cells(r + 1, c + 11) = .Item(8).innerText
On Error Resume Next
ws.Cells(r + 1, c + 12) = .Item(9).innerText
On Error Resume Next
ws.Cells(r + 1, c + 13) = .Item(10).innerText
On Error Resume Next
ws.Cells(r + 1, c + 14) = .Item(11).innerText
On Error Resume Next
ws.Cells(r + 1, c + 15) = .Item(12).innerText
On Error Resume Next
r = r + 1
End If
End With
Next
Next
End With
IE.Quit
Set IE = Nothing
Application.StatusBar = ""
Application.ScreenUpdating = True
MsgBox "data input complete"
End Sub

Answer 1

In addition to my comment above, here is the suggestion for a code optimisation. As I said, On Error Resume Next is not a good choice in most cases. You can avoid using it here by only taking over as many elements in a loop as are present. In addition, you should make your row and column handling less complicated. These are simply numbers that need to be managed. This can usually be done with +1 and resetting the column. Other corrections are not necessary.
The following code outputs exactly the same as your initial macro:
Sub Horse2()
Dim ws As Worksheet
Dim r As Long
Dim c As Long
Dim http As New XMLHTTP60
Dim html As New HTMLDocument
Dim node As HTMLHtmlElement
Dim nodeTr As HTMLHtmlElement
Dim oneElement As Long
Set ws = ThisWorkbook.Worksheets("Sheet1")
r = 2
c = 7
With http
.Open "GET", "https://www.racingandsports.com/thoroughbred/jockey/jake-bayliss/27461", False
.send
html.body.innerHTML = .responseText
End With
With html.getElementsByClassName("col-md-12 table-responsive")
For Each node In html.getElementsByClassName("table rns-table")
For Each nodeTr In node.getElementsByTagName("tr")
With nodeTr.getElementsByTagName("td")
If .Length Then
For oneElement = 0 To .Length - 1
ws.Cells(r, c) = .Item(oneElement).innerText
c = c + 1
Next oneElement
c = 7
r = r + 1
End If
End With
Next
r = r + 1
Next
End With
MsgBox "Data input complete"
End Sub