Apply attribute-sets on existing elements - json

Question

Working with a imported JSON data with a relatively flat hierarchical tree structure.
In the current code I am applying attribute-sets during the creation of elements.
Is it possible to create all the elements first and after that apply the attribute-sets?
It seems "use-attribute-sets" is an attribute, thus need to be added onto a element to work.
There are no error messages in my current code.
I am just looking to see if possible to do things in certain sequence as described below.
The reason for this planned change is to handle a bigger data volume thus perform the parsing and creation of element first, and only after that step, perform a unified way of adding attributes through attribute-sets.
The sequence I have:
[1] Create attribute sets.
[2] Group element names.
[3] Parse JSON to XML map.
[4] Build element, using attribute-sets and extract key value
The sequence I would like to perform:
[1] Create attribute sets (same as above).
[2] Group element names (same as above).
[3] Parse JSON to XML map (same as above).
[4] Build element names with corresponding key (split of above bullet 4).
[5] Add attribute-set based on template match in the code (split of above bullet 4).
JSON:
<data>
{
"store": {
"pencils": 43,
"milk": 21,
"rulers": 12,
"beer": 17
}
}
</data>
XSL:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:inventory="http://www.example.org/1"
xmlns:item="http://www.example.org/2"
expand-text="yes"
>
<xsl:output method="xml" indent="yes"/>
<xsl:mode on-no-match="shallow-skip"/>
<!-- [1] Create attribute sets -->
<xsl:attribute-set name="group-office">
<xsl:attribute name="contextRef">office</xsl:attribute>
</xsl:attribute-set>
<!-- [2] Group element names-->
<xsl:param name="group-office">pencils, rulers</xsl:param>
<xsl:param name="attributes-for-group-office" select="tokenize($group-office, ',\s*')"/>
<!-- [3] Parse JSON to XML -->
<xsl:template match="data">
<inventory:store>
<xsl:apply-templates select="json-to-xml(.)/*"/>
</inventory:store>
</xsl:template>
<!-- [4] Build element, using attribute-sets and extract key value -->
<xsl:template match="*[#key = 'store']/*[#key = $attributes-for-group-office]">
<xsl:for-each select=".">
<xsl:element name="item:{#key}" use-attribute-sets="group-office">
<xsl:value-of select="text()"/>
</xsl:element>
</xsl:for-each>
</xsl:template>
</xsl:transform>
Result
(current and how it should look like after sequence change of code):
<?xml version="1.0" encoding="UTF-8"?>
<inventory:store xmlns:inventory="http://www.example.org/1"
xmlns:item="http://www.example.org/2">
<item:pencils contextRef="office">43</item:pencils>
<item:rulers contextRef="office">12</item:rulers>
</inventory:store>

Answer 1

It is a rather artificial and not really easy separation as you can't inject an attribute set without creating an element so all you could do, if that helps, write a template with high-priority to select the element name and pass it on to a lower one that expects that name as a parameter and then do the real work, like before, to create the element with the attribute set:
<!-- [4] Extract key value for element name -->
<xsl:template match="*[#key = 'store']/*[#key = $attributes-for-group-office]" priority="10">
<xsl:next-match>
<xsl:with-param name="element-name" select="'item:' || #key"/>
</xsl:next-match>
</xsl:template>
<!-- [5] Build element and add attribute-set based on template match in the code -->
<xsl:template match="*[#key = 'store']/*[#key = $attributes-for-group-office]" priority="5">
<xsl:param name="element-name" required="yes"/>
<xsl:element name="{$element-name}" use-attribute-sets="group-office">
<xsl:value-of select="text()"/>
</xsl:element>
</xsl:template>
I am not sure that separation makes any sense but for the time being I can't think of anything else if you really want two separate templates. Of course the mode based suggestion by Siebe with a temporary tree is also an option but needs that temporary tree; or you could use the above and instead of relying on priorities to ensure the order of processing use a mode and push the same node through, for me it feels like the artificial and difficult separation as before:
<!-- [4] Build element and extract key value -->
<xsl:template match="*[#key = 'store']/*[#key = $attributes-for-group-office]">
<xsl:apply-templates select="." mode="add-attribute-sets">
<xsl:with-param name="element-name" select="'item:' || #key"/>
</xsl:apply-templates>
</xsl:template>
<!-- [5] Build element and add attribute-set based on template match in the code -->
<xsl:template match="*[#key = 'store']/*[#key = $attributes-for-group-office]" mode="add-attribute-sets">
<xsl:param name="element-name" required="yes"/>
<xsl:element name="{$element-name}" use-attribute-sets="group-office">
<xsl:value-of select="text()"/>
</xsl:element>
</xsl:template>

Answer 2

You can use modes, like this (Added some elements to make the wanted stages clear):
<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:inventory="http://www.example.org/1"
xmlns:item="http://www.example.org/2"
expand-text="yes"
>
<xsl:output method="xml" indent="yes"/>
<xsl:mode on-no-match="shallow-skip"/>
<xsl:mode name="useAttributeSet" on-no-match="shallow-skip"/>
<!-- [1] Create attribute sets -->
<xsl:attribute-set name="group-office">
<xsl:attribute name="contextRef">office</xsl:attribute>
</xsl:attribute-set>
<!-- [2] Group element names-->
<xsl:param name="group-office">pencils, rulers</xsl:param>
<xsl:param name="attributes-for-group-office" select="tokenize($group-office, ',\s*')"/>
<!-- [3] Parse JSON to XML -->
<xsl:template match="data">
<xsl:variable name="withoutAttributeSets">
<xsl:apply-templates select="json-to-xml(.)/*"/>
</xsl:variable>
<stages>
<stage>
<inventory:store>
<xsl:copy-of select="$withoutAttributeSets"/>
</inventory:store>
</stage>
<stage>
<inventory:store>
<xsl:apply-templates select="$withoutAttributeSets" mode="useAttributeSet"/>
</inventory:store>
</stage>
</stages>
</xsl:template>
<!-- [4] Build element names with corresponding key (split of above bullet 4). -->
<xsl:template match="*[#key = 'store']/*[#key = $attributes-for-group-office]">
<xsl:for-each select=".">
<xsl:element name="item:{#key}" >
<xsl:value-of select="text()"/>
</xsl:element>
</xsl:for-each>
</xsl:template>
<!-- [5] Add attribute-set based on template match in the code (split of above bullet 4). -->
<xsl:template match="*[local-name() = $attributes-for-group-office]" mode="useAttributeSet">
<xsl:element name="{name()}" use-attribute-sets="group-office">
<xsl:value-of select="text()"/>
</xsl:element>
</xsl:template>
</xsl:transform>
This wil give this result:
<?xml version="1.0" encoding="UTF-8"?>
<stages xmlns:inventory="http://www.example.org/1"
xmlns:item="http://www.example.org/2">
<stage>
<inventory:store>
<item:pencils>43</item:pencils>
<item:rulers>12</item:rulers>
</inventory:store>
</stage>
<stage>
<inventory:store>
<item:pencils contextRef="office">43</item:pencils>
<item:rulers contextRef="office">12</item:rulers>
</inventory:store>
</stage>
</stages>
Adjust it to your needs.
If you would like to reuse this [4]-stage some other way you also could save it like this:
<xsl:result-document href="stage-4.xml">
<inventory:store>
<xsl:copy-of select="$withoutAttributeSets"/>
</inventory:store>
</xsl:result-document>