Reading a nested list in a CSV column with Cassava - csv

Question

An example is easier to explain so I would like to parse this data into a datatype with cassava
title;authors
Cambridge Economic History;Ian MorrisWalter,ScheidelRichard,P Saller
I tried to do the following but it does not work (minimal not-working example) :
{-# LANGUAGE OverloadedStrings, DeriveGeneric #-}
module Library where
import Data.Csv
import Data.List.Split
import qualified Data.Vector as V
import qualified Data.Text as T
import GHC.Generics
data Book = Book {
title :: T.Text,
authors :: Authors
} deriving (Generic, Show)
type Authors = [T.Text]
instance FromNamedRecord Book
instance FromNamedRecord Authors
parseField "authors" =
pure $ splitOn "," ???
opts = defaultDecodeOptions {
decDelimiter = fromIntegral (ord ';')
}
main c = do
csvData <- BL.readFile "data.csv"
let res = decodeByNameWith opts csvData :: Either String (Header, V.Vector Book)
Is it possible to do it in Cassava ? Thanks!

Answer 1

The easiest way to do this is to write a customized FromNamedRecord instance for Book, instead of deriving the Generic one. It would look something like:
instance FromNamedRecord Book where
parseNamedRecord m = Book <$>
m .: "title" <*>
(T.splitOn "," <$> m .: "authors")
Here, m .: "authors" retrieves the authors field as a Text record, and the T.splitOn "," is fmapped (<$>) over that result to split the Text into [Text] by commas.
The full program:
{-# LANGUAGE OverloadedStrings #-}
module Library where
import Data.Char
import Data.Csv
import qualified Data.Vector as V
import qualified Data.Text as T
import Data.ByteString.Lazy as BL
data Book = Book {
title :: T.Text,
authors :: Authors
} deriving (Show)
type Authors = [T.Text]
instance FromNamedRecord Book where
parseNamedRecord m = Book <$>
m .: "title" <*>
(T.splitOn "," <$> m .: "authors")
opts = defaultDecodeOptions {
decDelimiter = fromIntegral (ord ';')
}
main = do
csvData <- BL.readFile "data.csv"
let res = decodeByNameWith opts csvData :: Either String (Header, V.Vector Book)
print res
giving:
λ> main
Right (["title","authors"],[Book {title = "Cambridge Economic History",
authors = ["Ian MorrisWalter","ScheidelRichard","P Saller"]}])
Note that this doesn't allow you to handle per-author quoting in the author list, so if you need to parse an author with an embedded comma, like:
Another Book;John Smith,"Anne Douglas, Jr."
you'll be out of luck. Cassava will refuse to parse an "authors" field with embedded quotes like this, and you'll end up having to write your own specialized CSV parser, I think.