MS Access: Compare two columns for Matches - Names in Different Order - ms-access

Question

I'm trying to compare two different columns in Access 2016. Both contain people's names, but not in the same order in both.
Name
Harris, Keisha
Banaghan, John
Garcia Silveira, Ana
NameFormat2
Keisha Melinda Harris
John C. Banaghan
Ana Lucia Garcia Silveira
Currently, when comparing these two columns, they all flag, as they are not exact matches.
The names in the first column are always shorter than the FULL name that lives in the second column.
Is there a way, be it a query or VBA or any other option, to say that if all of the names in the first column are contained in the second column, then it's a match and to move on?
Any help would be greatly appreciated!
Thanks,
Robert

Answer 1

Not sure if this is the best way, but you could create a VBA function that does the check by splitting the two fields into arrays and looping them. Something like this seems to work:
Function fCompareNames(strName1 As String, strName2 As String) As Boolean
On Error GoTo E_Handle
Dim astrName1() As String
Dim astrName2() As String
Dim intLoop1 As Integer
Dim intLoop2 As Integer
Dim intNames As Integer
Dim intMatch As Integer
strName1 = Replace(strName1, ",", "")
strName2 = Replace(strName2, ",", "")
astrName1 = Split(strName1, " ")
astrName2 = Split(strName2, " ")
intNames = UBound(astrName1) - LBound(astrName1) + 1
For intLoop1 = LBound(astrName1) To UBound(astrName1)
For intLoop2 = LBound(astrName2) To UBound(astrName2)
If astrName1(intLoop1) = astrName2(intLoop2) Then
intMatch = intMatch + 1
Exit For
End If
Next intLoop2
Next intLoop1
If intMatch = intNames Then fCompareNames = True
fExit:
On Error Resume Next
Exit Function
E_Handle:
MsgBox Err.Description & vbCrLf & vbCrLf & "fCompareNames", vbOKCancel + vbCritical, "Error: " & Err.Number
Resume fExit
End Function
You may need to add some extra Replaces to deal with things like "." in the name.
In the examples given, it returns true for the first two (Keisha Harris and John Banaghan) and false for the last (Ana Silveira) as there appears to be a spelling mistake in the second instance of her surname (Silbeira).
Regards,