How would I programmatically show items hidden on startup? - ms-access

Question

I have an Access database that is set to just show my forms and hide the ribbon and table explorer.
This works fine, except for me.
I want to be able to open the database from a shortcut, just as if I held down the Shift Key to bypass the startup routines.
I detect the command line parameter. I close the login form.
What all do I need to turn on to get back to a fully functioning version of Access without bothering with a shift key?
Here are a couple of candidates that I found from someone who was disabling everything. I need to turn them back on. But, I can't see how this worked in the original, and doesn't work at all for me.
StartUpShowStatusBar = True // Done
AllowShortcutMenus = True
AllowFullMenus = True
AllowBuiltInToolbars = True
AllowToolbarChanges = True
AllowSpecialKeys = True
UseAppIconForFrmRpt = True

Answer 1

You have already seen my answer here to hide ribbon and navigation pane. I am posting here to show them again by clicking a button. Below is both code to hide and then show ribbon and navigation pane.
Codes to hide-
Private Sub Form_Load()
On Error GoTo HarunErrHandler
'******************* Hide Ribbon and Navigation Pane ***************************
DoCmd.ShowToolbar "Ribbon", acToolbarNo
Call DoCmd.NavigateTo("acNavigationCategoryObjectType")
Call DoCmd.RunCommand(acCmdWindowHide)
'*******************************************************************************
Exit Sub
HarunErrHandler:
MessageBox = MsgBox("Error Number: " & Err.Number & vbCrLf & Err.Description, vbInformation, "Error")
End Sub
To show ribbon and left pane-
Private Sub cmdShow_Click()
On Error GoTo HarunErrHandler
'******************* Show Ribbon and Navigation Pane ***************************
DoCmd.ShowToolbar "Ribbon", acToolbarYes
Call DoCmd.SelectObject(acTable, , True)
'*******************************************************************************
Exit Sub
HarunErrHandler:
MessageBox = MsgBox("Error Number: " & Err.Number & vbCrLf & Err.Description, vbInformation, "Error")
End Sub

Answer 2

Based on Harun's answer, I was able to build this, which seems to bring everything back.
Private Sub Form_Load()
On Error GoTo ErrHandler
If CheckKeyFiles = True Then
Me!txtUID = "workflow"
Me!txtSID = GetSID("workflow")
End If
Me!txtVersionDate = "Version " & GetVersionDate()
If Command = "develop" Then
DoCmd.Close acForm, "Dialog_Login"
DoCmd.SelectObject acTable, , True
Application.SetOption "Show Status Bar", True
CurrentDb.Properties("AllowFullMenus") = True
CurrentDb.Properties("AllowBuiltInToolbars") = True
CurrentDb.Properties("AllowToolbarChanges") = True
CurrentDb.Properties("AllowSpecialKeys") = True
DoCmd.ShowToolbar "Ribbon", acToolbarYes
End If
Exit Sub
ErrHandler:
Dim Response
Response = MsgBox("Error Number: " & Err.Number & vbCrLf & Err.Description, vbInformation, "Error")
End Sub