MS access Convert Value Range to Separate row - ms-access

Question

How do I convert below from and To value range into single rows as shown in To in MS Access ? Value from and To could be either Numberic OR Non Numeric for from and To field as shown below. Some values does not have To.
From:
Role Field From To
Role1 F1 9411 9413
Role2 F2 9410 9412
Role1 F1 9999
Role1 F3 ABCD
Role2 F3 ABCD ZZZZ
To:
Role Field From To
Role1 F1 9411
Role1 F1 9412
Role1 F1 9413
Role2 F2 9410
Role2 F2 9411
Role2 F2 9412
Role1 F1 9999
Role1 F3 ABCD
Role2 F3 ABCD ZZZZ

Answer 1

What you can do is to loop the records in the first table, and then have an "inner" loop that goes between the two values to add data to the second table. Something like:
Sub sAddData()
On Error GoTo E_Handle
Dim db As DAO.Database
Dim rsSteer As DAO.Recordset
Dim rsData As DAO.Recordset
Dim lngLoop1 As Long
Dim lngFrom As Long
Dim lngTo As Long
Set db = DBEngine(0)(0)
db.Execute "DELETE * FROM tblTo;"
Set rsSteer = db.OpenRecordset("tblFrom")
If Not (rsSteer.BOF And rsSteer.EOF) Then
Set rsData = db.OpenRecordset("tblTo")
Do
If (IsNumeric(rsSteer("From"))) And (IsNumeric(rsSteer("To"))) Then
lngFrom = CLng(rsSteer("From"))
lngTo = CLng(rsSteer("To"))
For lngLoop1 = lngFrom To lngTo
rsData.AddNew
rsData("Role") = rsSteer("Role")
rsData("Field") = rsSteer("Field")
rsData("Value") = lngLoop1
rsData.Update
Next lngLoop1
ElseIf IsNumeric(rsSteer("From")) Then
rsData.AddNew
rsData("Role") = rsSteer("Role")
rsData("Field") = rsSteer("Field")
rsData("Value") = CLng(rsSteer("From"))
rsData.Update
End If
rsSteer.MoveNext
Loop Until rsSteer.EOF
End If
sExit:
On Error Resume Next
rsSteer.Close
rsData.Close
Set rsSteer = Nothing
Set rsData = Nothing
Set db = Nothing
Exit Sub
E_Handle:
MsgBox Err.Description & vbCrLf & vbCrLf & "sAddData", vbOKOnly + vbCritical, "Error: " & Err.Number
Resume sExit
End Sub
Code has been modified to deal with the possibility that either of the fields "From" or "To" may be Non-Numeric.
Regards,

Answer 2

You can use a Cartesian (multiplying) query.
First, create a small query:
SELECT DISTINCT Abs([id] Mod 10) AS N
FROM MSysObjects;
Save it as Ten, and then create the final query:
SELECT
RoleNumbers.Role,
RoleNumbers.Field,
[From] + [N] AS [Value]
FROM
RoleNumbers,
Ten
WHERE
[From] + [N] <= [To]
ORDER BY
RoleNumbers.Role,
[From] + [N];
Output: