Retrieve the value of a read-only input text box using VBScript - html

Question

I'm working with an Internet Explorer based application where I need to retrieve the value of an input text box that is read only. I've looked at other Stack Overflow questions and don't see anything about getting the value of a read only or hidden input box. I haven't found anything I can use on the internet either.
Here's the HTML code for the input box I'm trying to get the value from:
<div class="col-xs-10 col-sm-9 col-md-6 col-lg-5 form-field input_controls">
<div class="hidden" ng-non-bindable="">
<input name="sys_original.x_opt_im_issue_task.number" id="sys_original.x_opt_im_issue_task.number" type="hidden" value="TSK0111065" />
</div>
<input class="form-control disabled " id="sys_readonly.x_opt_im_issue_task.number" readonly="readonly" ng-non-bindable="" value="TSK0111065" />
</div>
Here's the VBScript code I'm trying to use to get the value of the input text box that isn't working:
UPDATED
Option Explicit
Dim WShell, objShell, objIE
Dim strMessage, URL, ErrMsg, URLFound, Browser
Dim EN_ID, EntNowID
Sub Main()
On Error Resume Next
Set WShell = CreateObject("WScript.Shell")
Set objShell = CreateObject("Shell.Application")
If Err.Number <> 0 Then ShowError("Failed to create objects")
On Error GoTo 0
Check_EN
SetEverythingToNothing
End Sub
'---------------------------------
Sub ShowError(strMessage)
MsgBox strMessage & vbNewline & vbNewline & "Error number: " & Err.Number & vbNewline & "Source: " & Err.Source & vbNewline & "Description: " & Err.Description
Err.Clear
SetEverythingToNothing
End Sub
'------------------------------
Sub Check_EN()
URL = "https://enterprisenow.mysite.com"
ErrMsg = "EnterpriseNOW is not open or on the incorrect page. Please check & rerun the macro."
Check_URL
ErrMsg = ""
Set EN_ID = objIE.document.getElementById("sys_readonly.x_opt_im_issue_task.number")
EntNowID = EN_ID.Value
MsgBox EntNowID
End Sub
'------------------------------
Function Check_URL()
URLFound = False
For Each Browser In objShell.Windows()
If InStr(UCase(Browser.LocationURL), UCase(URL)) > 0 Then
If InStr(UCase(Browser.FullName), "IEXPLORE.EXE") Then
If Err.Number = 0 Then
Set objIE = Browser
URLFound = True
Exit For
End If
End If
End If
Next
If URLFound = False Then
MsgBox "Unable to find URL."
SetEverythingToNothing
End If
End Function
'-----------------------------
Sub SetEverythingToNothing()
Set WShell = Nothing
Set objShell = Nothing
Set Browser = Nothing
Set objIE = Nothing
End Sub
I'm able to set the objIE object and find the URL, but I'm receiving "Run-time error '424': Object required". Is it because the input text box is hidden or read only? I'm also wondering if it has anything to do with nested div tags?

Answer 1

Try the following - it worked for me. What I noticed is that if I accessed:
objIE.document.getElementById("sys_readonly.x_opt_im_issue_task.number").Value
more than once, I got the error: Object required
However if I used 'Set' and created an object like so:
Set tasknumber = objIE.document.getElementById("sys_readonly.x_opt_im_issue_task.number")
I could then access the value multiple times without receiving the error.
Option Explicit
Dim objShell : Set objShell = CreateObject("shell.application")
Dim URL : URL = "https://enterprisenow.mysite.com/"
Dim URLFound : URLFound = False
Dim Browser, tasknumber, tasknumbervalue
For Each Browser In objShell.Windows()
If InStr(UCase(Browser.FullName), "IEXPLORE.EXE") Then
If InStr(UCase(Browser.LocationURL), UCase(URL)) > 0 Then
If Err.Number = 0 Then
Set tasknumber = Browser.document.getElementById("sys_readonly.x_opt_im_issue_task.number")
If (NOT IsNull(tasknumber) And NOT tasknumber Is Nothing) Then
tasknumbervalue = tasknumber.value
End If
Set tasknumber = Nothing
Exit For
End If
End If
End If
Next
MsgBox tasknumbervalue
Set Browser = Nothing
Set objShell = Nothing

Answer 2

Well, it's not the solution I was hoping for, but it's easier than trying to get the number from the input field.
I had a feeling that the iframe tag may be preventing me from detecting the input field ID, so I looked at the iframe and saw that the TSK number in the input field was also in the iframe tag.
Instead of trying this:
EN_ID = objIE.document.getElementById("sys_readonly.x_opt_im_issue_task.number").Value
I was able to use this:
iframeName = Split(objIE.document.getElementById("gsft_main").Title, " | ") 'Title = "TSK0111065 | Issue Task | ServiceNow"
EN_ID = iframeName(0)