Can I skip inputting optional function parameters in tcl? - tcl

Question

I know I can make tcl functions with optional input parameters. So if you don't enter a value for those parameters they can take on the default value that you give them. My question is when I call a function with optional parameters is it possible to skip the input of some and enter others? Like if there are 2x optional parameters how would I enter a value for the second parameter rather than the first?
I haven't really tried anything specifically because I'm not sure how to get around this problem.
proc area { height width {normalization 1.0} {scaling 1.0} {
....
}
[area 3 4 3.5]
Is there a way I could call area without changing the default value for normalization, while entering a value for scaling?
If I wanted a scaling value of 3.5 I can't really enter it in without also entering a value for normalization?

Answer 1

Yes, that's correct; if you want a scaling value of 3.5, you cannot enter it without also entering a value for normalization with the way the proc was written.
You can do something a bit more towards what you want to do with some tweaking (there's a whole wiki article discussing about ways to do this). A quick example with an array:
proc area {height width args} {
# Put the remaining parameters in an array, you might want to do validation checks before that
array set options $args
# If certain parameters are not provided, give default values
if {"-normalization" ni [array names options]} {
set options(-normalization) 1.0
}
if {"-scaling" ni [array names options]} {
set options(-scaling) 1.0
}
puts "Normalization: $options(-normalization)"
puts "Scaling: $options(-scaling)"
}
area 1 2 -normalization 3.5
# => Normalization: 3.5
# => Scaling: 1.0
area 1 2 -scaling 3.5
# => Normalization: 1.0
# => Scaling: 3.5
area 1 2
# => Normalization: 1.0
# => Scaling: 1.0

Answer 2

The pattern I use is this:
proc area {height width args} {
# The default values
set defaults {-normalization 1.0 -scaling 1.0}
# Merge with the actual arguments provided
set params [dict merge $defaults $args]
# Just extract the variables I care about using [dict update] with an empty body
dict update params -normalization norm -scaling scale {}
# Demonstrate what's been extracted
puts "Parameters: $height $width $norm $scale"
}
area 2 3 -scaling 17.3
This isn't perfect since it doesn't warn/error about unexpected arguments, provide a discovery mechanism, or handle argument name abbreviation, but it's simple and cheap and fairly fast. There have been proposals for changing that (I'm aware of two TIPs: 457, 479) but none have really gained traction so far; it's an area that is a tricky compromise between flexibility and performance.
(If you use the variable name as the actual parameter name and don't care at all about wrong arguments, you can just use dict with to do the extraction.)
A shorter version (using the same basic idea) might be:
proc area {height width args} {
array set {} [dict merge {-normalization 1.0 -scaling 1.0} $args]
puts "Parameters: $height $width $(-normalization) $(-scale)"
}
This uses the variable with the empty name as an array. Yes, that's legal (and relatively convenient) but I've never really warmed to it myself.

Answer 3

There have been proposals for changing that (I'm aware of two TIPs:
457, 479) but none have really gained traction so far.
If you are willing to use an established Tcl extension (https://next-scripting.org/), you can benefit from optional named parameters when implementing a proc:
package req nsf
nsf::proc area {height width {-normalization 1.0} {-scaling 1.0}} {
puts "arguments: $height $width $normalization $scaling"
}
area 1 2 -normalization 3.5
# arguments: 1 2 3.5 1.0
area 1 2 -scaling 3.5
# arguments: 1 2 1.0 3.5
area 1 2
# arguments: 1 2 1.0 1.0