Having trouble with an auto updater - ms-access

Question

I am new to coding in access and I came across a simple way to update a database remotely. Attached is the directions and a stripped down version of my database. Can anyone tell me what I am doing wrong? Thanks in advance!!
This is a great module that works wonderful, but I wanted to let
people know you can do the version checking without using VBA, and
simply have an Updater application that runs the VBA to delete your
local copy and download the fresh version off the server.
I use a table called AppConstants on the server's backend that has two
columns: ConstantTitle and ConstantValue. One of the rows has
ConstantTitle set to "AppVersion" and ConstantValue set to the version
number.
Then I have a field with visibility set to False on my main form
called VersionNo, and I set this field's value to ="VersionNumber"
(where VersionNumber is the actual version number, e.g. ="1.25"). On
the Main Form's OnLoad event, I have a macro that runs a DLookup in an
IF command:
if DLookUp("[ConstantValue]", "tblAdmin", "[ConstantTitle] ='AppVersion'")<>[Forms]![frmMain]![VersionNo] Then RunCode OpenUpdater()
Quit Access
End If
The code for OpenUpdater:
Code:
Function OpenUpdater() 'This sets the name of the code to call later
Dim accapp As Access.Application
Set accapp = New Access.Application
accapp.OpenCurrentDatabase ("C:\$Data\MyUpdater.accde") 'Starts up this file
accapp.Visible = True
End Function
What it's doing: The macro checks the value of the VersionNumber in the table on the server. When I update the app copy
on the server, I set a new version number in here and set my app
copy's VersionNo field to the same number. When you're running the old
version, your app sees that the version numbers don't match, and then
it executes the Macro's 'Then' commands: it runs the OpenUpdater code
and shuts itself off.
The OpenUpdater code simply starts the MyUpdater.accde program, which
is by default installed on the user's PC along with the application
itself. The OpenUpdater program executes the following
code:
DoCmd.ShowToolbar "Ribbon", acToolbarNo
'Copy the new version to the C drive
Dim SourceFile, DestinationFile As String
SourceFile = "Z:\Server\MyProgram.accde" 'Where to get the fresh copy
DestinationFile = "C:\$Data\MyProgram.accde" 'Where to put it
With CreateObject("Scripting.FileSystemObject")
.copyfile SourceFile, DestinationFile, True 'This line does the acual copy and paste
End With
'Reopen MyProgram
Dim accapp As Access.Application
Set accapp = New Access.Application
accapp.OpenCurrentDatabase ("C:\$Data\MyProgram.accde")
accapp.Visible = True
End Function
This Function is called in a Macro within MyUpdater, and the command just after the RunCode in this Macro is QuitAccess,
which shuts off the Updater.
So my main program, when you open the main form, checks the version
number on the server. If they're different, the main program starts
the updater and then shuts itself down. The updater copies the fresh
version off the server and pastes it in the correct place on the C
drive, then starts up the program and shuts itself down.
From the end-user's perspective, the program starts, immediately
quits, and then starts again a second or so later and now it's
updated. It works awesome.
My issue is when I open up the copy database, the update doesn't run
but it runs when I go into the myupdater database and manually run the
macro. Here is the macro
If DLookUp("[ConstantValue]","AppConstants","[ConstantTitle]='AppVersion'")<>[Forms]![NavMain]![VersionNo]
Then RunCode FunctionName OpenUpdater()
Quit Access
Here is the function
Function OpenUpdater() 'This sets the name of the code to call later
Dim accapp As Access.Application
Set accapp = New Access.Application
accapp.OpenCurrentDatabase ("C:\Users\Tyrone\Desktop\MyUpdater.accde") 'Starts up this file
accapp.Visible = True
End Function

Answer 1

The posted code is similar to what I use. I also used script approach but I liked having all in Access and not having to install script file on each user machine. However, I did not use macro, only VBA. The VBA is behind a Login form that opens by default. Form is bound to Updates table so DLookup() is not used for the version check. gstrBasePath is a global constant declared in a general module. This uses Windows Shell so it is necessary to set reference to Microsoft Shell Controls And Automation library. Unfortunately, IT updated computers with additional restrictions that won't allow programmatic copy of files at all (was originally limited to C:\ root location) and this no longer works for me.
Private Sub Form_Load()
'Check for updates to the program on start up - if values don't match then there is a later version
If Me.tbxVersion <> Me.lblVersion.Caption Then
'because administrator opens the master development copy, only run this for non-administrator users
If DLookup("Permissions", "Users", "UserNetworkID='" & Environ("UserName") & "'") <> "admin" Then
'copy Access file
CreateObject("Scripting.FileSystemObject").CopyFile _
gstrBasePath & "Program\Install\MaterialsDatabase.accdb", "c:\", True
'allow enough time for file to completely copy before opening
Dim Start As Double
Start = Timer
While Timer < Start + 3
DoEvents
Wend
'load new version - SysCmd function gets the Access executable file path
'Shell function requires literal quote marks in the target filename string argument, apostrophe delimiters fail, hence the quadrupled quote marks
Shell SysCmd(acSysCmdAccessDir) & "MSAccess.exe " & """" & CurrentProject.FullName & """", vbNormalFocus
'close current file
DoCmd.Quit
End If
Else
'tbxVersion available only to administrator to update version number in Updates table
Me.tbxVersion.Visible = False
Call UserLogin
End If
End Sub
Private Sub tbxUser_AfterUpdate()
If Me.tbxUser Like "[A-z][A-z][A-z]" Or Me.tbxUser Like "[A-z][A-z]" Then
CurrentDb.Execute "INSERT INTO Users(UserNetworkID, UserInitials, Permissions) VALUES('" & VBA.Environ("UserName") & "', '" & UCase(Me.tbxUser) & "', 'staff')"
Call UserLogin
Else
MsgBox "Not an appropriate entry.", vbApplicationModal, "EntryError"
End If
End Sub
Private Sub UserLogin()
Me.tbxUser = DLookup("UserInitials", "Users", "UserNetworkID='" & Environ("UserName") & "'")
If Not IsNull(Me.tbxUser) Then
CurrentDb.Execute "UPDATE Users SET ComputerName='" & VBA.Environ("ComputerName") & "' WHERE UserInitials='" & Me.tbxUser & "'"
DoCmd.OpenForm "Menu", acNormal, , "UserInitials='" & Me.tbxUser & "'", , acWindowNormal
DoCmd.Close acForm, Me.Name, acSaveNo
End If
End Sub