How to display date as text in Access report - ms-access

Question

I'm trying to get Access to create a certificate for me. I've got almost everything worked out except for the date. I want the date to display as text.
I'm able to accomplish this with a module in Excel, but when I input it into Access as a function, it gives me a #Name? error. Here's what I have in the function (again, this works in Excel):
Function DateToWords(ByVal xRgVal As Date) As String
Dim xYear As String
Dim Hundreds As String
Dim Decades As String
Dim xTensArr As Variant
Dim xOrdArr As Variant
Dim xCardArr As Variant
xOrdArr = Array("1st", "2nd", "3rd", "4th", "5th", "6th", _
"7th", "8th", "9th", "10th", "11th", "12th", _
"13th", "14th", "15th", "16th", "17th", "18th", _
"19th", "20th", "21st", "22nd", _
"23rd", "24th", "25th", "26th", _
"27th", "28th", "29th", "30th", "31st")
xCardArr = Array("", "one", "two", "three", "tour", _
"five", "six", "seven", "eight", "nine", _
"ten", "eleven", "twelve", "thirteen", _
"fourteen", "fifteen", "sixteen", _
"seventeen", "eighteen", "nineteen")
xTensArr = Array("twenty", "thirty", "forty", "fifty", _
"sixty", "seventy", "eighty", "ninety")
xYear = CStr(Year(xRgVal))
Decades = Mid$(xYear, 3)
If CInt(Decades) < 20 Then
Decades = xCardArr(CInt(Decades))
ElseIf CInt(Decades) Like "*0" Then
Decades = xTensArr(CInt(Left$(Decades, 1)) - 2)
Else
Decades = xTensArr(CInt(Left$(Decades, 1)) - 2) & "-" & _
xCardArr(CInt(Right$(Decades, 1)))
End If
Hundreds = Mid$(xYear, 2, 1)
If CInt(Hundreds) Then
Hundreds = xCardArr(CInt(Hundreds)) & " hundred "
Else
Hundreds = ""
End If
DateToWords = "This " & xOrdArr(Day(xRgVal) - 1) & " day of" & _
Format$(xRgVal, " mmmm, ") & _
xCardArr(CInt(Left$(xYear, 1))) & _
" thousand " & Hundreds & Decades
End Function
Code in Access that calls the function. This is in the text box on the report:
=DateToWords([Forms]![FrmMakeCert]![Date])
n Excel, this takes the date that I specify in a cell (e.g. 12/27/18) and turns it into:
"This 27th day of December, two-thousand eighteen"
That's what I'd like to accomplish in the Access report, pulling the date from a form.

Answer 1

Issue was caused by using the same name for both user-defined function and module namely DateToWords.
You should use different names.
Rename the module to, for instance, mdlDateToWords.

Answer 2

Steps to use.
First create a module in access and paste your codes.
Suppose in report you are displaying date to text in a textbox name txtDateText
In txtDateText data source enter following
=DateToWords([Forms]![Form1]![txtDate])
Remember: Form1 must be open and contain valid date otherwise it will show error. Form1 is form name, so it will be different in your case. Also text box name.
File download link