"InvalidOperationException : Connection must be valid and open" On MySqlConnection - mysql

Question

I was working on a VB.Net project (first time, I was previously working in VBA) and I seem to have trouble establishing connecion with a MariaDB/MySQL database.
I wanted to get all rows for one column to use it as source for a ComboBox named CBClient in a Form
Here my codes so far:
First class: ClassSQL
Imports MySql.Data.MySqlClient
Imports MySql.Data.Types
Public Class ClassSQL
Public Shared ConfigSQL As String =
"DATABASE=(My actual DB);DATA SOURCE=(IP of the server);USER ID=(UserID);PASSWORD=(Password)"
Public Shared ConnectDB As New MySqlConnection(ConfigSQL)
End Class
And the Form class:
Imports MySql.Data.MySqlClient
Public Class NewDossier
Private Sub NewDossier_Load(sender As Object, e As EventArgs) Handles MyBase.Load
GetCBClient()
End Sub
Sub GetCBClient()
ClassSQL.ConnectDB.Open()
Dim Requete As String = "SELECT NomClient FROM MSClients"
Dim Query As New MySqlCommand(Requete, ClassSQL.ConnectDB)
Dim rs As MySqlDataReader = Query.ExecuteReader
Do While rs.Read
CBClient.Items.Add(rs.GetString("NomClient"))
Loop
ClassSQL.ConnectDB.Close()
End Sub
End Class
On ClassSQL.ConnectDB.Open() in the Form class I have the exception:
InvalidOperationException : Connection must be valid and open
Is my connection wrong somehow? Or is it something I did wrong?
Is there a way to specify the port?

Answer 1

In ADO.Net, it is not generally a good idea to try to re-use the same connection object throughout an application, because of a feature called Connection Pooling. The connector is already managing this for you. Instead, it really is better to just create a new connection instance for most queries. Just keep the connection string handy and re-use that. This works especially well in conjunction with the IDisposable/Using pattern.
Additionally, it's a good idea to put your queries in the same Class or Module as your connection string, isolated from the rest of the application, where each query is a function that returns the data and (usually) accepts an argument telling it what data to find.
Public Module SQL
'Making this private helps ensure you remember to put database activities here in this class.
Private ConnectionString As String = "DATABASE=(My actual DB);DATA SOURCE=(IP of the server);USER ID=(UserID);PASSWORD=(Password)"
'You could also design this function to return a DataTable object, if Iterator blocks aren't your thing
Public Iterator Function GetMSClients() As IEnumerable(Of String)
Dim Requete As String = "SELECT NomClient FROM MSClients"
Using cn As New MySqlConnection(ConnectionString), _
cmd As New MySqlCommand(Requete, cn)
cn.Open()
Using rdr As MySqlDataReader = cmd.ExecuteReader()
While rdr.Read()
Yield rdr.GetString("NomClient")
End While
End Using
End Using
End Function
End Module
Public Class NewDossier
Private Sub NewDossier_Load(sender As Object, e As EventArgs) Handles MyBase.Load
CBClient.Items.AddRange(SQL.GetMSClients().ToArray())
End Sub
End Class