ERLANG with JSON - json

Question

I run following command in erlang,
os:cmd("curl -k -X GET http://10.210.12.154:10065/iot/get/task").
It gives a JSON output like this,
{"data":[
{"id":1,"task":"Turn on the bulb when the temperature in greater than 28","working_condition":1,"depending_value":"Temperature","action":"123"},
{"id":2,"task":"Trun on the second bulb when the temperature is greater than 30","working_condition":0,"depending_value":"Temperature","action":"124"}
]}
I want to categorize this data to Id, task, depending_value, action. It is like putting them in to a table. I want to easily find what is the depending value, working condition & action for Id=1. How can I do this?

Answer 1

It gives a JSON output like this.
{"data":[{"id":1,"t ...
Highly doubtful. The docs say that os:cmd() returns a string, which does not start with a {. Note also that a string is not even an erlang data type, rather double quotes are a shortcut for creating a list of integers, and a list of integers is not terribly useful in your case.
Here are two options:
Call list_to_binary() on the list of integers returned by os:cmd() to covert to a binary.
Instead of os:cmd(), use an erlang http client, like hackney, which will return the json as a binary.
The reason you want a binary is because then you can use an erlang json module, like jsx, to convert the binary into an erlang map (which might be what you are after?).
Here's what that will look like:
3> Json = <<"{\"data\": [{\"x\": 1, \"y\": 2}, {\"a\": 3, \"b\": 4}] }">>.
<<"{\"data\": [{\"x\": 1, \"y\": 2}, {\"a\": 3, \"b\": 4}] }">>
4> Map = jsx:decode(Json, [return_maps]).
#{<<"data">> =>
[#{<<"x">> => 1,<<"y">> => 2},#{<<"a">> => 3,<<"b">> => 4}]}
5> Data = maps:get(<<"data">>, Map).
[#{<<"x">> => 1,<<"y">> => 2},#{<<"a">> => 3,<<"b">> => 4}]
6> InnerMap1 = hd(Data).
#{<<"x">> => 1,<<"y">> => 2}
7> maps:get(<<"x">>, InnerMap1).
1
...putting them in to a table. I want to easily find what is the
depending value, working condition & action for Id=1.
Erlang has various table implementations: ets, dets, and mnesia. Here is an ets example:
-module(my).
-compile(export_all).
get_tasks() ->
Method = get,
%See description of this awesome website below.
URL = <<"https://my-json-server.typicode.com/7stud/json_server/db">>,
Headers = [],
Payload = <<>>,
Options = [],
{ok, 200, _RespHeaders, ClientRef} =
hackney:request(Method, URL, Headers, Payload, Options),
{ok, Body} = hackney:body(ClientRef),
%{ok, Body} = file:read_file('json/json.txt'), %Or, for testing you can paste the json in a file (without the outer quotes), and read_file() will return a binary.
Map = jsx:decode(Body, [return_maps]),
_Tasks = maps:get(<<"data">>, Map).
create_table(TableName, Tuples) ->
ets:new(TableName, [set, named_table]),
insert(TableName, Tuples).
insert(_Table, []) ->
ok;
insert(Table, [Tuple|Tuples]) ->
#{<<"id">> := Id} = Tuple,
ets:insert(Table, {Id, Tuple}),
insert(Table, Tuples).
retrieve_task(TableName, Id) ->
[{_Id, Task}] = ets:lookup(TableName, Id),
Task.
By default, an ets set type table ensures that the first position in the inserted tuple is the unique key (or you can explicitly specify another position in the tuple as the unique key).
** If you have a github account, I discovered a really cool website that allows you to place a json file in a new repository on github, and the website will serve up that file as json. Check it out at https://my-json-server.typicode.com:
How to
Create a repository on GitHub (<your-username>/<your-repo>)
Create a db.json file [in the repository].
Visit https://my-json-server.typicode.com/<your-username>/<your-repo> to
access your server
You can see the url I'm using in the code, which can be obtained by clicking on the link at the provided server page and copying the url in your web browser's address bar.
In the shell:
.../myapp$ rebar3 shell
===> Verifying dependencies...
===> Compiling myapp
src/my.erl:2: Warning: export_all flag enabled - all functions will be exported
Erlang/OTP 20 [erts-9.3] [source] [64-bit] [smp:4:4] [ds:4:4:10] [async-threads:1] [hipe] [kernel-poll:false]
Eshell V9.3 (abort with ^G)
1> ===> The rebar3 shell is a development tool; to deploy applications in production, consider using releases (http://www.rebar3.org/docs/releases)
===> Booted unicode_util_compat
===> Booted idna
===> Booted mimerl
===> Booted certifi
===> Booted ssl_verify_fun
===> Booted metrics
===> Booted hackney
1> Tasks = my:get_tasks().
[#{<<"action">> => <<"123">>,
<<"depending_value">> => <<"Temperature">>,<<"id">> => 1,
<<"task">> =>
<<"Turn on the bulb when the temperature in greater than 28">>,
<<"working_condition">> => 1},
#{<<"action">> => <<"124">>,
<<"depending_value">> => <<"Temperature">>,<<"id">> => 2,
<<"task">> =>
<<"Trun on the second bulb when the temperature is greater than 30">>,
<<"working_condition">> => 0}]
2> my:create_table(tasks, Tasks).
ok
3> my:retrieve_task(tasks, 1).
#{<<"action">> => <<"123">>,
<<"depending_value">> => <<"Temperature">>,<<"id">> => 1,
<<"task">> =>
<<"Turn on the bulb when the temperature in greater than 28">>,
<<"working_condition">> => 1}
4> my:retrieve_task(tasks, 2).
#{<<"action">> => <<"124">>,
<<"depending_value">> => <<"Temperature">>,<<"id">> => 2,
<<"task">> =>
<<"Trun on the second bulb when the temperature is greater than 30">>,
<<"working_condition">> => 0}
5> my:retrieve_task(tasks, 3).
** exception error: no match of right hand side value []
in function my:retrieve_task/2 (/Users/7stud/erlang_programs/old/myapp/src/my.erl, line 58)
6>
Note that the id is over to the right at the end of one of the lines. Also, if you get any errors in the shell, the shell will automatically restart a new process and the ets table will be destroyed, so you have to create it anew.
rebar.config:
{erl_opts, [debug_info]}.
{deps, [
{jsx, "2.8.0"},
{hackney, ".*", {git, "git://github.com/benoitc/hackney.git", {branch, "master"}}}
]}.
{shell, [{apps, [hackney]}]}. % This causes the shell to automatically start the listed apps. See https://stackoverflow.com/questions/40211752/how-to-get-an-erlang-app-to-run-at-starting-rebar3/45361175#comment95565011_45361175
src/myapp.app.src:
{application, 'myapp',
[{description, "An OTP application"},
{vsn, "0.1.0"},
{registered, []},
{mod, {'myapp_app', []}},
{applications,
[kernel,
stdlib
]},
{env,[]},
{modules, []},
{contributors, []},
{licenses, []},
{links, []}
]}.
But, according to the rebar3 dependencies docs:
You should add each dependency to your app or app.src files:
So, I guess src/myapp.app.src should look like this:
{application, 'myapp',
[{description, "An OTP application"},
{vsn, "0.1.0"},
{registered, []},
{mod, {'myapp_app', []}},
{applications,
[kernel,
stdlib,
jsx,
hackney
]},
{env,[]},
{modules, []},
{contributors, []},
{licenses, []},
{links, []}
]}.