Read Perl JSON structure - json

Question

I get the JSON from request:
use HTTP::Tiny;
my $response = HTTP::Tiny->new->get('https://jsonplaceholder.typicode.com/todos/1');
print "-------------------**------------------- \n";
my $content = $response->{content};
print $content->[0]->{name};
Response:
[
{
"id": 1,
"name": "Leanne Graham", "username": "Bret", "email": "Sincere#april.biz",
"address": {
"street": "Kulas Light", "suite": "Apt. 556",
"city": "Gwenborough", "zipcode": "92998-3874", "geo": { "lat": "-37.3159",
"lng": "81.1496" } }, "phone": "1-770-736-8031 x56442", "website": "hildegard.org",
"company": {
"name": "Romaguera-Crona",
"catchPhrase": "Multi-layered client-server neural-net",
"bs": "harness real-time e-markets"
}
},
{
"id": 2,
"name": "Ervin Howell",
"username": "Antonette",
"email": "Shanna#melissa.tv",
"address": {
"street": "Victor Plains",
"suite": "Suite 879",
"city": "Wisokyburgh",
"zipcode": "90566-7771",
"geo": {
"lat": "-43.9509",
"lng": "-34.4618"
}
}
]
How to read every content of the json return variable. I've tried this:
print $content->[0]->{name};
, but return nothing.
How to read through the JSON structure of perl?

Answer 1

Your variable contains a string that represents a data structure in the JSON format. You need to convert it to a Perl data structure in order to use traverse it in Perl. At this point, it's just a bunch of text, and HTTP::Tiny does not care what kind of data it returns.
Core Perl brings the JSON::PP module starting from version 5.13.9 (with the 5.14 release).
use strict;
use warnings;
use JSON::PP 'decode_json';
use Data::Printer;
my $json = qq({ "foo" : "bar" });
my $decoded = decode_json($json);
p $decoded;
print $decoded->{foo};
This will output:
\ {
foo "bar"
}
bar
If you've got a newer Perl and have some other stuff installed, you probably also have JSON::MaybeXS, which will pick the fastest JSON parser available automatically.
Now if you wanted your user agent to know how to do this in multiple places, you can easily create a sub class. I've done a rudimentary implementation here. Save it in a new file HTTP/Tiny/DecodeJSON.pm in the right folder. I would place it under lib in your script's directory.
.
├── lib
│ └── HTTP
│ └── Tiny
│ └── DecodeJSON.pm
└── script.pl
I would also suggest adding extensive error handling.
package HTTP::Tiny::DecodeJSON;
use strict;
use warnings;
use JSON::PP 'decode_json';
use parent 'HTTP::Tiny';
# we need this to not throw a warning in HTTP::Tiny::_agent()
use constant VERSION => '0.01';
sub get_json {
my $self = shift;
my $res = $self->get(#_);
# add error handling here ...
return decode_json $res->{content};
}
1;
You can then reuse it wherever you like. To use it in your script, you need to add the lib directory to the list of directories that Perl looks for it's modules.
use strict;
use warnings;
use Data::Printer;
use lib 'lib';
use HTTP::Tiny::DecodeJSON;
my $decoded = HTTP::Tiny::DecodeJSON->new->get_json(
'https://jsonplaceholder.typicode.com/todos/1'
);
p $decoded;

Answer 2

simbabque has explained a lot,
and it is useful to have an example of subclassing HTTP::Tiny. I would add the following
I believe that Cpanel::JSON::XS, despite its convoluted name, is the superior JSON module on CPAN
There is no $content->[0]->{name} element in the data returned from that URL, although I imagine that is because you are working on it. Thank you for posting a usable data source: it makes questions so much more pleasant to answer
It's pretty much essential to check whether the HTTP request has succeeded, and die with an explanatory message if there was a problem. It's just an extra statement
die $response->{reason} unless $response->{success};
Here's how I would write your code. Instead of selecting the field as you do I have used Data::Dump
to display the contents of the structure
use strict;
use warnings 'all';
use HTTP::Tiny;
use Cpanel::JSON::XS 'decode_json';
my $response = HTTP::Tiny->new->get('https://jsonplaceholder.typicode.com/todos/1');
die $response->{reason} unless $response->{success};
my $data = decode_json $response->{content};
use Data::Dump;
dd $data;
output
{
completed => bless(do{\(my $o = 0)}, "JSON::PP::Boolean"),
id => 1,
title => "delectus aut autem",
userId => 1,
}
As you can see, $content->[0]->{name} would never work because the data is a hash rather than an array, and there is no hash key name anywhere. But the Latin is a strong indicator that the server has been updated since your question so this is not a problem
The value $data->{completed} is boolean, and should probably be tested with
if ( $data->{completed} ) { ... }
to decide what to do with the response