Expand Range of Numbers in SQL [closed] - ms-access

Question

Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 4 years ago.
Improve this question
Is there an SQL code that can be written to expand these cluster of numbers in the Destination Zip Range column?
Screenshot is attached below
Using Access 2016, thanks

Answer 1

You will need DAO to run this.
Create a helper function to split the zip codes:
Public Function ExpandCluster(ByVal ClusterList As String) As Variant
Dim Clusters As Variant
Dim Items As Variant
Dim ZipCodes() As String
Dim Index As Integer
Dim FirstCode As Integer
Dim LastCode As Integer
Dim ThisCode As Integer
Dim Redimmed As Boolean
Clusters = Split(ClusterList, ",")
ReDim ZipCodes(0)
For Index = LBound(Clusters) To UBound(Clusters)
Items = Split(Clusters(Index), "-")
FirstCode = Val(Items(LBound(Items)))
LastCode = Val(Items(UBound(Items)))
While FirstCode <= LastCode
Debug.Print Index, FirstCode
If Redimmed Then
ReDim Preserve ZipCodes(UBound(ZipCodes) + 1)
Else
Redimmed = True
End If
ZipCodes(UBound(ZipCodes)) = Format(FirstCode, "000")
FirstCode = FirstCode + 1
Wend
Next
ExpandCluster = ZipCodes
End Function
Then use this in a function where you create a record for each zip code extracted with that function:
Public Sub FillTable()
Dim Source As DAO.Recordset
Dim Target As DAO.Recordset
Dim ZipCodes() As String
Dim Index As Integer
Set Source = CurrentDb.OpenRecordset("Select * From tblParent Where ZipRange Is Not Null")
Set Target = CurrentDb.OpenRecordset("Select * From tblChild")
While Not Source.EOF
ZipCodes = ExpandCluster(Source!ZipRange.Value)
For Index = LBound(ZipCodes) To UBound(ZipCodes)
Target.AddNew
' Assign foreign key.
Target!FK.Value = Source!Id.Value
' Assign this zip code.
Target!ZipCode.Value = ZipCodes(Index)
'
' Insert lines for other field values.
'
Target.Update
Next
Source.MoveNext
Wend
Source.Close
Target.Close
End Sub
Some generic names are used. Of course, adjust these to your actual table and field names.