XSLT to HTML for below case - html

Question

I'm practicing XSLT and trying to achieve below scenario using XSLT. Please kindly help :-)
I have below input XML:
<Items>
<item><lineType>STX</lineType></item>
<item><lineType>STZ</lineType></item>
<item><lineType>STY</lineType></item>
<item><lineType>STY</lineType></item>
<item><lineType>STZ</lineType></item>
<item><lineType>STX</lineType></item>
</Items>
I want to display above XML as below HTML table format:
Example:
Banner - 1
STX
STX
Banner - 2
STY
STY
Banner - 3
STZ
STZ

Answer 1

The following XSLT-2.0 code will satisfy your needs:
<?xml version="2.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*" /> <!-- remove spaces between elements -->
<xsl:template match="Items">
<xsl:for-each-group select="item" group-by="lineType">
<xsl:sort select="lineType" /> <!-- sort output alphabetically -->
<xsl:value-of select="concat('Banner - ',position(),'
')" />
<xsl:for-each select="current-group()"> <!-- iterate over the elements of the current group -->
<xsl:value-of select="concat(.,'
')" />
</xsl:for-each>
</xsl:for-each-group>
</xsl:template>
</xsl:stylesheet>
On the other hand an XSLT-1.0 way is the following template applying the concept of Muenchian Grouping:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>
<xsl:key name="unique" match="item" use="lineType" />
<xsl:strip-space elements="*" />
<xsl:template match="Items">
<xsl:for-each select="item[generate-id() = generate-id(key('unique',lineType)[1])]">
<xsl:sort select="lineType" />
<xsl:value-of select="concat('Banner - ',position(),'
')" />
<xsl:for-each select="key('unique',lineType)">
<xsl:value-of select="concat(.,'
')" />
</xsl:for-each>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
The output in both cases is:
Banner - 1
STX
STX
Banner - 2
STY
STY
Banner - 3
STZ
STZ