2010 Access - setting Excel hyperlink in a shape starts another Excel task - ms-access

Question

I have a 2010 Access vba procedure that creates a workbook and adds sheets. I then create a sheet (sheet1) that is a "menu" for the user the use for hyperlinking to the appropriate sheet. The code looks like this:
with ws
iLeft = 350
iTop = 140
iWidth = 160
iHeight = 30
.Shapes.AddShape(msoShapeRoundedRectangle, iLeft, iTop, iWidth, iHeight).Select
i = wks.Shapes.Count
.Shapes.Range(i).ShapeStyle = msoShapeStylePreset33
.Shapes.Range(i).TextFrame2.VerticalAnchor = msoAnchorMiddle
.Shapes.Range(i).TextFrame2.TextRange.Characters.Text = "All Data"
.Shapes.Range(i).TextFrame2.TextRange.Characters.Font.Bold = msoTrue
.Shapes.Range(i).TextFrame2.TextRange.Characters(1, 8). _
ParagraphFormat.Alignment = msoAlignCenter
With .Shapes.Range(i).TextFrame2.TextRange.Characters(1, 8).Font
.NameComplexScript = "+mn-cs"
.NameFarEast = "+mn-ea"
.Fill.Visible = msoTrue
.Fill.ForeColor.RGB = RGB(255, 255, 255)
.Fill.ForeColor.TintAndShade = 0
.Fill.ForeColor.Brightness = 0
.Fill.Transparency = 0
.Fill.Solid
.Size = 11
.Name = "+mn-lt"
End With
Set HyperLinkShape = wks.Shapes(i)
HyperSubAddress = "'All Data'!A1"
.Hyperlinks.Add Anchor:=HyperLinkShape, Address:="", SubAddress:=HyperSubAddress
end with
There are hundreds of other lines of code, but I have narrowed down that the
.Hyperlinks.Add...
statement is causing a second occurrence of Excel to start. Normally, that happens because I should be referencing the worksheet somewhere in the statement. I tried:
.Hyperlinks.Add Anchor:=ws.HyperLinkShape, Address:="", SubAddress:=HyperSubAddress
and
.Hyperlinks.Add Anchor:=HyperLinkShape, Address:="", SubAddress:=ws.HyperSubAddress
but both of these gave me a compiler error.
Any suggestions on how I can fix this issue?

Answer 1

I cannot reproduce this.
The following standalone procedure runs in Access 2010. Both hyperlinks work.
After disposing of all objects (and oExcel.Quit), there is no more Excel process.
Note: you can do without all the Set obj = Nothing, then the Excel process closes after the procedure is finished, when all local variables go out of scope.
Public Sub TestExcelShapeHyperlink()
Dim oExcel As Excel.Application
Dim wkb As Excel.Workbook
Dim wks As Excel.Worksheet
Dim shp As Excel.Shape
Set oExcel = CreateObject("Excel.Application")
With oExcel
.UserControl = True
.Visible = True
End With
Set wkb = oExcel.Workbooks.Add
Set wks = wkb.ActiveSheet
' Note: there is no reason to select the shape
Set shp = wks.Shapes.AddShape(msoShapeRoundedRectangle, 10, 10, 200, 100)
' Use the created object to set its properties
With shp
.ShapeStyle = msoShapeStylePreset10
.TextFrame2.TextRange.Font.Bold = msoTrue
.TextFrame2.VerticalAnchor = msoAnchorMiddle
.TextFrame2.TextRange.Characters.Text = "TEST TEST TEST"
.TextFrame2.TextRange.Characters.ParagraphFormat.Alignment = msoAlignCenter
.TextFrame2.TextRange.Characters.Font.Bold = msoTrue
End With
' Name 2nd sheet for hyperlink target
wkb.Worksheets(2).Name = "All Data"
' Hyperlink 1 with anchor = shape
wks.Hyperlinks.Add Anchor:=shp, Address:="", SubAddress:="'All Data'!A1"
' Hyperlink 2 with anchor = a random cell
wks.Hyperlinks.Add Anchor:=wks.Range("B11"), Address:="", SubAddress:="'All Data'!D5", TextToDisplay:="Click me, I'm a link!"
Stop ' 1 Excel process
Set shp = Nothing
Set wks = Nothing
wkb.SaveAs "D:\foo.xlsx"
wkb.Close
Set wkb = Nothing
oExcel.Quit
Set oExcel = Nothing
Stop ' 0 Excel processes
End Sub