Can deadlock occur if there is not any transaction explicity defined? - sql-server-2008

Question

If we don't have a transaction block (SQL Server 2008)
BEGIN TRAN
END TRAN
Just DELETE, UPDATE, INSERT or INSERT SELECT
is it possible to get a deadlock? If so, can you give me an example?

Answer 1

Yes, a deadlock can occur between 2 different sessions even without an explicit transaction. The example script below generates a deadlock on my test box.
--prep script
CREATE TABLE dbo.Example(
Col1 int NOT NULL CONSTRAINT PK_Example PRIMARY KEY
, Col2 int NOT NULL
, Col3 int NOT NULL
, Col4 char(2000) NULL
);
GO
WITH
t10 AS (SELECT n FROM (VALUES(0),(0),(0),(0),(0),(0),(0),(0),(0),(0)) t(n))
,t1k AS (SELECT 0 AS n FROM t10 AS a CROSS JOIN t10 AS b CROSS JOIN t10 AS c)
,t1m AS (SELECT ROW_NUMBER() OVER (ORDER BY (SELECT 0)) AS num FROM t1k AS a CROSS JOIN t1k AS b CROSS JOIN t1k AS c)
INSERT INTO dbo.Example(Col1, Col2, Col3)
SELECT num, num % 100, num % 150
FROM t1m
WHERE num <= 1000000;
GO
CREATE INDEX idx_Col2 ON dbo.Example(Col2);
CREATE INDEX idx_Col3 ON dbo.Example(Col3);
GO
CHECKPOINT;
DBCC DROPCLEANBUFFERS;
GO
--run this on session 1 after changing time to a near future value
WAITFOR TIME '12:00:00';
UPDATE dbo.Example SET Col3 = 1 WHERE Col2 = 1;
GO
--run this on session 2 after changing time to same time as session 1
WAITFOR TIME '12:00:00';
UPDATE dbo.Example SET Col2 = 2 WHERE Col3 = 1;
GO
I used a large number of rows in this script because it reliably reproduced a deadlock even on a fast machine. Remember that deadlocks are a matter of timing so I expect one could use fewer rows on a slow box to also reproduce a deadlock.
Even with a small table, efficient queries, and automatic single-statement transactions, deadlocks are possible (albeit unlikely) when queries access the same resource via different access paths. The queries in this example use different indexes so the different locking order can lead to a deadlock.