Access DB - Get last index number - ms-access

Question

I am trying to insert a new employee into a table with a custom ID field when a form saves (Before Insert). To create the custom ID I am using the first 4 letters of the last name and the first 2 numbers of the first name, followed by a 2 digit number that is generated by the number of matching employee names:
i.e.
John Smith = SMITJO01 (first entry)
John Smith = SMITJO02 (second John Smith)
However, I do not know how to add the unique index (01, 02) into the function depending on how many other matching names are in the list:
Function GetNextEmployeeId(ByVal lastName As String, ByVal firstName As String) As String
Dim strNameComp As String
Dim nSEQ As Long
strNameComp = Left(lastName, 4) & Left(firstName, 2)
End Function
Edit:
Since the EMPLOYEE_ID is the primary key, it keeps giving meNull errors when I try to save a new entry, both on the BeforeUpdate and BeforeInsert form events.
Updating with my final solution, I had to modify because it was being finicky about formatting to numbers. Thanks to both you guys for the help!
Function GetNextEmployeeId(ByVal lastName As String, ByVal firstName As String) As String
Dim strNameComp As String
'Dim varMax As Var
Dim nSEQ As Long
strNameComp = UCase(Left(lastName, 4)) & UCase(Left(firstName, 2))
varMax = DMax("EMPLOYEE_ID", "EMPLOYEES", "EMPLOYEE_ID LIKE '" & strNameComp & "*'")
If IsNull(varMax) Then
' no one there yet
nSEQ = 1
Else
' split off the number part, convert to number, add 1
nSEQ = Val(Right$(varMax, 2)) + 1
End If
GetNextEmployeeId = UCase(strNameComp) & Format(nSEQ, "00")
End Function

Answer 1

Following Andre's suggestion of using DMax, try something like this:
Function GetNextEmployeeId(ByVal lastName As String, ByVal firstName As String) As String
Dim strPre As String
Dim varMax As String
strPre = Left(lastName, 4) & Left(firstName, 2)
varMax = DMax("EmployeeId", "tblEmployee", "EmployeeId LIKE '" & strPre & "*'")
GetNextEmployeeId = strPre & Right("0" & Right(Nz(varMax, "0"), 2) + 1, 2)
End Function

Answer 2

Get the maximum Employee ID that matches the Name:
varMax = DMax("EmployeeId", "tblEmployee", "EmployeeId LIKE '" & strNameComp & "*'")
and then you need a distinction:
If IsNull(varMax) Then
' no one there yet
nSEQ = 1
Else
' split off the number part, convert to number, add 1
nSEQ = Val(Right$(varMax, 2)) + 1
End If