SQL query not working in Access - ms-access

Question

My first time using Access
The below query works in SQL Server but when I bring it into access I get the below error message.
DECLARE #CandidateNumber INT
SET #CandidateNumber = 5921368
UPDATE XXX
SET #CandidateNumber = CandidateNumber = #CandidateNumber + 1
GO
Error message: invalid sql statement expected 'delete' 'Insert','Select','Update'

Answer 1

It does not work because Access uses a different dialect of SQL than SQL Server. In particular Access SQL (JET) does not support DECLARE-ing variables.
Unfortunately, JET SQL is not well-documented by Microsoft, but there are third-party resources available (for example, a JET Database Wikibook).

Answer 2

Perhaps all you need is a query with a row counter.
You can use this function and just add the CandidateNumber value:
Public Function RowCounter( _
ByVal strKey As String, _
ByVal booReset As Boolean, _
Optional ByVal strGroupKey As String) _
As Long
' Builds consecutive RowIDs in select, append or create query
' with the possibility of automatic reset.
' Optionally a grouping key can be passed to reset the row count
' for every group key.
'
' Usage (typical select query):
' SELECT RowCounter(CStr([ID]),False) AS RowID, *
' FROM tblSomeTable
' WHERE (RowCounter(CStr([ID]),False) <> RowCounter("",True));
'
' Usage (with group key):
' SELECT RowCounter(CStr([ID]),False,CStr[GroupID])) AS RowID, *
' FROM tblSomeTable
' WHERE (RowCounter(CStr([ID]),False) <> RowCounter("",True));
'
' The Where statement resets the counter when the query is run
' and is needed for browsing a select query.
'
' Usage (typical append query, manual reset):
' 1. Reset counter manually:
' Call RowCounter(vbNullString, False)
' 2. Run query:
' INSERT INTO tblTemp ( RowID )
' SELECT RowCounter(CStr([ID]),False) AS RowID, *
' FROM tblSomeTable;
'
' Usage (typical append query, automatic reset):
' INSERT INTO tblTemp ( RowID )
' SELECT RowCounter(CStr([ID]),False) AS RowID, *
' FROM tblSomeTable
' WHERE (RowCounter("",True)=0);
'
' 2002-04-13. Cactus Data ApS. CPH
' 2002-09-09. Str() sometimes fails. Replaced with CStr().
' 2005-10-21. Str(col.Count + 1) reduced to col.Count + 1.
' 2008-02-27. Optional group parameter added.
' 2010-08-04. Corrected that group key missed first row in group.
Static col As New Collection
Static strGroup As String
On Error GoTo Err_RowCounter
If booReset = True Then
Set col = Nothing
ElseIf strGroup <> strGroupKey Then
Set col = Nothing
strGroup = strGroupKey
col.Add 1, strKey
Else
col.Add col.Count + 1, strKey
End If
RowCounter = col(strKey)
Exit_RowCounter:
Exit Function
Err_RowCounter:
Select Case Err
Case 457
' Key is present.
Resume Next
Case Else
' Some other error.
Resume Exit_RowCounter
End Select
End Function
See in-line comments for typical usage.

Answer 3

If you are working with a table linked from SQL-Server, you can use a pass-through query in Access. This type of query is not exectued by the Access engine (JetEngine) but is sent directly to SQL-Server which executes it.
If you are deling with a true Access query, then use a parameter.
See: Passing parameter to query for Access database