BATCH - Remove some characters from filename - csv

Question

I've files with this name:
FirstPart_SecondPart_ThirdPart.zip_FourthPart_FifthPartX.csv
where X is a one-digit number.
It should be renamed via batch scripting as:
FirstPart_SecondPart_ThirdPart.zip_FifthPartX.csv
So I'd like to remove the FourthPart. Please note that all the parts ALWAYS HAVE the same lenght. FirstPart is always 7 digits, SecondPart is always 9 digits...etc...
Here is what I've tried:
ren \*.zip_*FifthPart?.csv *.zip_FifthPart?.csv
But it does not work.
Please any help?

Answer 1

Within the appropriate directory
…at the Command prompt:
For /F "EOL=_Tokens=1-4*Delims=_" %A In ('Dir/B/A-D "*_*_*_*_*.csv"') Do #Ren "%A_%B_%C_%D_%E" "%A_%B_%C_%E"
…in a batch file:
#For /F "EOL=_Tokens=1-4*Delims=_" %%A In ('Dir/B/A-D "*_*_*_*_*.csv"'
) Do #Ren "%%A_%%B_%%C_%%D_%%E" "%%A_%%B_%%C_%%E"
Because you are already certain of the file name format and character numbers I feel that the best approach would be to utilise Where instead of Dir.
For example, in a batch file:
FirstPart is always 7 digits, SecondPart is always 9 digits, ThirdPart is always 6 digits, FourthPart is always 5 digits and FifthPart is always 8 digits.
#For /F "EOL=_Tokens=1-4*Delims=_" %%A In (
'Where .:"???????_?????????_??????_?????_????????.csv"'
) Do #Ren "%%A_%%B_%%C_%%D_%%E" "%%A_%%B_%%C_%%E"

Answer 2

You can use a for /F loop to split and rebuild the file names:
for /F "delims= eol=|" %%F in ('dir /B /A:-D "*_*_*_*_*.csv"') do (
for /F "tokens=1-4* delims=_ eol=_" %%A in ("%%F") do (
ren "%%F" "%%A_%%B_%%C_%%E"
)
)
Given that none of the parts contain underscores (_) on their own and none of them are empty, a single loop is sufficient:
for /F "tokens=1-4* delims=_ eol=_" %%A in ('dir /B /A:-D "*_*_*_*_*.csv"') do (
ren "%%A_%%B_%%C_%%D_%%E" "%%A_%%B_%%C_%%E"
)
Here is an approach with an additional filter for file names using findstr in order to exclude files that do not match the name specifications:
for /F "tokens=1-4* delims=_ eol=_" %%A in ('
dir /B /A:-D "*_*_*_*_*.csv" ^| findstr /I "^[^_][^_]*_[^_][^_]*_[^_][^_]*_[^_][^_]*_[^_].*\.csv$"
') do (
ren "%%A_%%B_%%C_%%D_%%E" "%%A_%%B_%%C_%%E"
)

Answer 3

Two possibilities to solve this:
(1) As all parts always have the same length, you can just use substrings to cut the FourthPart_ part:
#ECHO OFF
SETLOCAL EnableDelayedExpansion
FOR /F "tokens=*" %%G IN ('DIR /B *.csv') DO (
SET new_filename=%%G
SET new_filename=!new_filename:~0,35!!new_filename:~46!
ECHO REN "%%G" "!new_filename!"
)
(2) Alternatively, if FourthPart_ is a static string, you might also get away with removing the FourthPart_ using search & replace:
#ECHO OFF
SETLOCAL EnableDelayedExpansion
FOR /F "tokens=*" %%G IN ('DIR /B *.csv') DO (
SET new_filename=%%G
SET new_filename=!new_filename:FourthPart_=!
ECHO REN "%%G" "!new_filename!"
)
These batch files will only output the commands to be issued. Remove the ECHO once you've inspected the output and you're confident it does what you want.