Identifying where a table begins in a Word doc - ms-access

Question

I have a specific work doc that is produced daily which includes a paragraph of text followed by a table with a bunch of customer data. I need to import that data into an Access table.
I've found code, which I'll include below, which does just that. However it's not working as intended. Rather it's not working at all. I anticipate that it's because the word doc begins not with a table, but text.
So I have two options. 1) Find a way to format each document so it contains only the table (I'll have to automate this because we receive dozens of these files each day) or 2) adjust the code so that it detects only the table in the doc.
Is there a good way of doing either of these things?
Option Compare Database
Private Sub cmdImport_Click()
Dim appWord As Word.Application, doc As Word.Document
Dim dbs As DAO.Database, rst As DAO.Recordset, strDoc As String
Set appWord = CreateObject("Word.Application") 'establish an instance of word
strDoc = CurrentProject.Path & "\cmoSheet.docx" 'set string to document path and file
Set doc = appWord.Documents.Open(strDoc) 'establish the document
Set dbs = CurrentDb 'establish the database to use (this is our current Database)
Set rst = dbs.OpenRecordset("cmoSheetTbl") 'establish the recordset
With doc.Tables(1) 'target table 1 in cmoSheet.docx
For i = 2 To .Rows.Count 'cycle through rows in Tables(1) [we skip the first row because the table has headers]
With rst
.AddNew 'creating a new record
![ReviewerName] = doc.Tables(1).Cell(i, 1).Range.Text
![ProductDesc] = doc.Tables(1).Cell(i, 2).Range.Text
![NPI] = doc.Tables(1).Cell(i, 3).Range.Text
![LastName] = doc.Tables(1).Cell(i, 5).Range.Text
![FirstName] = doc.Tables(1).Cell(i, 6).Range.Text
![ProviderType] = doc.Tables(1).Cell(i, 7).Range.Text
![Specialty] = doc.Tables(1).Cell(i, 8).Range.Text
![BatchID] = doc.Tables(1).Cell(i, 9).Range.Text
![AdditionalDocs?] = doc.Tables(1).Cell(i, 10).Range.Text
.Update 'update the whole record
End With
Next 'go to next row in Tables(1)
End With
rst.Close: Set rst = Nothing 'close and clear recordset
db.Close: Set rst = Nothing 'close and clear database
doc.Close: Set doc = Nothing 'close and clear document
appWord.Quit: Set appWord = Nothing 'close and clear MS Word
End Sub

Answer 1

A nested With must be related to the outer With. In addition, adding Option Explicit will reveal a couple of errors in your code.
db.Close: Set rst = Nothing
should be:
dbs.Close: Set dbs= Nothing
Since you create an early binding to Word when declaring the variables, you can simply use the New keyword to create an instance:
Dim appWord As Word.Application, doc As Word.Document
Set appWord = New Word.Application
If you want to create a late bind to Word, remove the reference to it and declare the variable(s) as Object:
Dim appWord As Object, doc As Object
Set appWord = CreateObject("Word.Application")
Try this:
Private Sub cmdImport_Click()
Dim appWord As Word.Application, doc As Word.Document
Dim dbs As DAO.Database, rst As DAO.Recordset, strDoc As String
Set appWord = New Word.Application 'establish an instance of word
strDoc = CurrentProject.Path & "\cmoSheet.docx" 'set string to document path and file
Set doc = appWord.Documents.Open(strDoc) 'establish the document
Set dbs = CurrentDb 'establish the database to use (this is our current Database)
Set rst = dbs.OpenRecordset("cmoSheetTbl") 'establish the recordset
With doc.Tables(1) 'target table 1 in cmoSheet.docx
Dim i As Integer
For i = 2 To .Rows.count 'cycle through rows in Tables(1) [we skip the first row because the table has headers]
rst.AddNew 'creating a new record
rst![ReviewerName] = .Cell(i, 1).Range.Text
rst![ProductDesc] = .Cell(i, 2).Range.Text
rst![NPI] = .Cell(i, 3).Range.Text
rst![LastName] = .Cell(i, 5).Range.Text
rst![FirstName] = .Cell(i, 6).Range.Text
rst![ProviderType] = .Cell(i, 7).Range.Text
rst![Specialty] = .Cell(i, 8).Range.Text
rst![BatchID] = .Cell(i, 9).Range.Text
rst![AdditionalDocs?] = .Cell(i, 10).Range.Text
rst.Update 'update the whole record
Next 'go to next row in Tables(1)
End With
rst.Close: Set rst = Nothing 'close and clear recordset
dbs.Close: Set dbs = Nothing 'close and clear database
doc.Close: Set doc = Nothing 'close and clear document
appWord.Quit: Set appWord = Nothing 'close and clear MS Word
End Sub