Deserialize Application Insights Analytics with Json.net - json

Question

I'm trying to use Json.net to deserialize JSON from Application Insights Analytics (AIA) into my class. I'm not sure if I'm approaching it right, but I use LINQ-to-JSON to get at the data section of the JSON and then try to deserialize to my class using this code:
Dim rawjson As String = GetTelemetry()
Dim o As JObject = JObject.Parse(rawjson)
Dim ds = DirectCast(o("Tables")(0)("Rows"), JArray)
Dim Sessions As List(Of Session) = JsonConvert.DeserializeObject(Of List(Of Session))(ds)
This fails as the JSON from AIA is in this format:
"Rows": [
[
"Boy",
"9",
"",
"",
"0",
"0",
"22",
"0"
],
[
"Boy",
"9",
"",
"",
"0",
"0",
"41",
"0"
],
Notice the data for the individual rows is an array rather than an object.
My Session class is defined like this:
Public Class Session
Public Property Gender As String
Public Property Age As Integer
Public Property SessionVids As Integer
Public Property TotalVids As Integer
Public Property ChildUse As Integer
Public Property ChildTime As Integer
Public Property AdultUse As Integer
Public Property AdultTime
End Class
Can someone please explain how to do this?

Answer 1

You can convert the JArray of rows (ds) into a list of Session objects like this:
Dim Sessions As List(Of Session) =
ds.Select(Function(ja)
Dim s As New Session()
s.Gender = ja(0).Value(Of String)()
s.Age = GetInt(ja(1))
s.SessionVids = GetInt(ja(2))
s.TotalVids = GetInt(ja(3))
s.ChildUse = GetInt(ja(4))
s.ChildTime = GetInt(ja(5))
s.AdultUse = GetInt(ja(6))
s.AdultTime = GetInt(ja(7))
Return s
End Function).ToList()
where GetInt is a helper function defined like this:
Public Function GetInt(jt As JToken) As Integer
Dim i As Integer
If Integer.TryParse(jt.Value(Of String)(), i)
Return i
End If
Return 0
End Function
The helper function is needed since the JSON has empty strings for some of the values while your class requires valid integers.
Fiddle: https://dotnetfiddle.net/GqFcov