Bounding box using Arma 3 scripting - sqf

Question

This is a very basic question. I am new to Arma scripting and I'm trying to get a bounding box around a moving vehicle (named pickup_truck). How do I run this script?
http://www.armaholic.com/page.php?id=30924
say for eg: [pickup_truck] execVM "bb_object_1.sqf";
I was able to get this script ( http://killzonekid.com/arma-3-bounding-box-utility/ ) but the bounding box does not move along with the vehicle!

Answer 1

This is because vehicle's object bbox defined outside of "Draw3D" mission event handler. Once defined, this variable used in event handler code being unchanged.
Originally, KK's example not designed to show bounding box around moving vehicles.
If you want to show bounding box around moving vehicles, you must define bbox variable every event occur (inside event handler code). Then coordinates of bounding box points will be actual on each frame.
addMissionEventHandler function not allow to pass parameters inside handler code. Therefore KK's example used global variables bbox and bboxr to store bounding box info for acces to it from event handler code.
In such cases i prefer to use function BIS_fnc_addStackedEventHandler. This solution allow to pass parameters to event handler code (pickup_truck in code below).
Adopted KK's example:
[
"Whatever_EVH_Name_You_Want",
"onEachFrame",
{
private _veh = _this select 0;
private _bb = {
_bbx = [_this select 0 select 0, _this select 1 select 0];
_bby = [_this select 0 select 1, _this select 1 select 1];
_bbz = [_this select 0 select 2, _this select 1 select 2];
_arr = [];
0 = {
_y = _x;
0 = {
_z = _x;
0 = {
0 = _arr pushBack (_veh modelToWorld [_x,_y,_z]);
} count _bbx;
} count _bbz;
reverse _bbz;
} count _bby;
_arr pushBack (_arr select 0);
_arr pushBack (_arr select 1);
_arr
};
private _bbox = boundingBox _veh call _bb;
private _bboxr = boundingBoxReal _veh call _bb;
for "_i" from 0 to 7 step 2 do {
drawLine3D [
_bbox select _i,
_bbox select (_i + 2),
[0,0,1,1]
];
drawLine3D [
_bboxr select _i,
_bboxr select (_i + 2),
[0,1,0,1]
];
drawLine3D [
_bbox select (_i + 2),
_bbox select (_i + 3),
[0,0,1,1]
];
drawLine3D [
_bboxr select (_i + 2),
_bboxr select (_i + 3),
[0,1,0,1]
];
drawLine3D [
_bbox select (_i + 3),
_bbox select (_i + 1),
[0,0,1,1]
];
drawLine3D [
_bboxr select (_i + 3),
_bboxr select (_i + 1),
[0,1,0,1]
];
};
},
[pickup_truck]
] call BIS_fnc_addStackedEventHandler;