Tcl Expect spawn -open send_user - two different behaviors - tcl

Question

I am back to Tcl/Expect after a long time. It seems Expect isn't behaving the same for default spawn_id and explicit. AFAIK this wasn't the case.
I am using Expect 5.45 on Ubuntu. On an input file input/input.found.txt like:
~$ more input/input.found.txt
hello
World!
hello
<intentional blank new line>
Consider Expect code (use send_user or puts) where both cases differ only by -i $file1 only:
package require Expect
puts "---"
set file [open "input/input.found.txt" r]
spawn -open $file
set file1 $spawn_id
expect -i $file1 {
-re ".ello" {
send_user "found\r\n"; # should print BUT doesn't print
}
-re ".orld" {
send_user "found the world!\r\n"; # shouldn't print, doesn't print
}
eof { puts "not found" }
}
exp_close $file1
if {[info exists $file ] } {
close $file
}
puts "---"
set file [open "input/input.found.txt" r]
spawn -open $file
set file1 $spawn_id
expect {
-re ".ello" {
send_user "found\r\n"; # should print, prints
}
-re ".orld" {
send_user "found the world!\r\n"; # shouldn't print, doesn't print
}
eof { puts "not found" }
}
exp_close $file1
if {[info exists $file ] } {
close $file
}
puts "---"
I expect outputs for both the cases to be the same but they aren't. The output I get is:
---
spawn [open ...]
hello
World!
hello
---
spawn [open ...]
hello
World!
hello
found
---
(Notice missing found in the first case.)
Where is my assumption about output wrong? Why explicit specification of spawn_id through -i (at least in file handling case) altering behavior of send_user or puts?

Answer 1

Your first expect command is not what you think. The expect command will take seperate arguments, or a single list of arguments.
Your first expect command has 3 arguments, so it takes the -i $file as an option specifying the spawn id and the last argument as a pattern without any body. That multi-line pattern doesn't match your file content. But even if it did, nothing would be printed as there is no body for that pattern.
Your second expect command has all arguments inside braces. The expect command then expands that list into 8 arguments.
The easiest fix for your program is to put the -i $file1 inside the braces, as in:
expect {
-i $file1
-re ".ello" {
send_user "found\r\n"; # should print BUT doesn't print
}
-re ".orld" {
send_user "found the world!\r\n"; # shouldn't print, doesn't print
}
eof { puts "not found" }
}