Format elapsed time value string - csv

Question

I receive a CSV file daily in which I filter to look for certain data. This file requires a lot of manual effort within Excel to filter and format the data. I am devising a VBScript to look at each line to return only the data needed to reduce the manual effort.
Within the CSV file is a "time seen" string which is formatted strangely. The "time seen" data differs from line to line. An example of this data is the following:
3hrs27min 35sec
35min 20sec
8min 38sec
1days1hrs25min 30sec
5days12hrs9min 48sec
I am using this code snippet to remove the "days", "hrs", "min ", and "sec" from the data and replace them with a ":".
strLastField0 = arrFields(9)
strLastField1 = Replace(strLastField0,"min ",":")
strLastField2 = Replace(strLastField1,"hrs",":")
strLastField3 = Replace(strLastField2,"days",":")
strLastField4 = Replace(strLastField3,"sec","")
The result is the following:
d:h:m:s
3:27:35
35:20
8:38
1:1:25:30
5:12:9:48
I am looking to have the data come out formatted in the following manner instead of what it currently is.
hh:mm:ss
03:27:35
00:35:20
00:08:38
25:01:25
132:09:48
Here is a function in which I have been working with to accomplish this, but my attempts have failed to get the formatting like I want.
Function funcFormatTime(TimeString)
Dim TimeArray
Dim h, m, s, hh, mm, ss
TimeArray = Split(TimeString, ":", -1, 1)
d = TimeArray(0)
h = TimeArray(1)
m = TimeArray(2)
s = TimeArray(3)
Do Until s < 60
s = s - 60
m = m + 1
Loop
Do Until m < 60
m = m - 60
h = h + 1
Loop
Do Until h < 24
h = h - 24
Loop
If Len(Trim(h)) = 1 Then hh = "0" & h Else hh = h
If Len(Trim(m)) = 1 Then mm = "0" & m Else mm = m
If Len(Trim(s)) = 1 Then ss = "0" & s Else ss = s
funcFormatTime = hh & ":" & mm & ":" & ss
End Function

Answer 1

This uses a regular expression to split the input strings using the .Replace method with a function pointer that will receive as arguments each of the elements in the string if present or an Empty value if not present.
Option Explicit
Dim aStrings
aStrings = Array( _
"3hrs27min 35sec", _
"35min 20sec", _
"8min 38sec", _
"1days1hrs25min 30sec", _
"5days12hrs9min 48sec" _
)
Dim sTime
For Each sTime in aStrings
WScript.Echo funcFormatTime( sTime )
Next
Function funcFormatTime( inputString )
With New RegExp
.Pattern = "^(?:([0-9]+)days)?(?:([0-9]+)hrs)?(?:([0-9]+)min)?(?:\s*([0-9]+)sec)"
funcFormatTime = .Replace( inputString, GetRef("funcCalcTime") )
End With
End Function
Function funcCalcTime( matchedString, d, h, m, s, offset, originalString )
funcCalcTime = LeftZeroPad( CLng("0" & d) * 24 + Clng("0" & h), 2) & ":" & _
LeftZeroPad( CLng("0" & m), 2) & ":" & _
LeftZeroPad( CLng("0" & s), 2)
End Function
Function LeftZeroPad( value, length )
LeftZeroPad = CStr(value)
If Len(LeftZeroPad) < length Then
LeftZeroPad = Right(String(length, "0") & CStr(LeftZeroPad), length)
End If
End Function
Each of the elements in the regular expression have the form
(?:([0-9]+)days)?
Where (?: )? means that the parenthesis do not define a capture group (?:) and that this group could or couldn't be present (the closing ?). Inside this expression there is a ([0-9]+) that define a capture group that match a sequence of numeric digits. Capture groups are passed as arguments to the replace function, where the only work to do is properly format the values.