Access: Update query with list of users - ms-access

Question

I have an access db with some tables, queries, macro... etc
One table is a result of a query and it's used to populate a sharepoint. This table has a column [User] that has no records but I would like to fill with a list of users before upload to the sharepoint.
Ex. the table has 58 rows and I whant to use the 10 users.
Row1 - User 1
Row2 - User 2
...
Row10 - User 10
Row11 - User 1
and so on...
I realy don't know what is the best way to do this.
Can anyone help me? Thanks.

Answer 1

I would suggest using Visual Basic for Applications (VBA) for this.
Create a new Module and then create a procedure that will populate the data.
Its relatively simple - you want to loop through all the users and update the parent table.
For my code, I am assuming that you have one table holding your query results (with the empty "User" field), and that you have another table holding all of your users (using the field name "UserName")
Public Sub PopulateUsers()
Dim dbs As DAO.Database
Dim rstUsers As DAO.Recordset
Dim rstComputers As DAO.Recordset
' Open up our tables
Set dbs = CurrentDb
Set rstUsers = dbs.OpenRecordset("Users")
' If there are no users then complain and quit
If rstUsers.EOF Then
rst.Close
MsgBox "There are no users to populate", vbInformation, "Error"
Set rstUsers = Nothing
Exit Sub
End If
Set rstComputers = dbs.OpenRecordset("ComputerUsers")
' Loop through all of our computer records
Do Until rstComputers.EOF
rstComputers.Edit
rstComputers!User = rstUsers!UserName
rstComputers.Update
rstUsers.MoveNext
If rstUsers.EOF Then
rstUsers.MoveFirst
End If
rstComputers.MoveNext
Loop
' Close tables
rstUsers.Close
rstComputers.Close
' Clear object references to free up memory
Set dbs = Nothing
Set rstUsers = Nothing
Set rstComputers = Nothing
debug.print "Users Populated"
End Sub
You can press Control + G to open the immediate window and then type "PopulateUsers".