TCL login program doesn't work - tcl

Question

I am making a login program in TCL. I have the following code:
package require Tk
set usr [open "$env(HOME)\\AppData\\Roaming\\basicfile\\USR.txt" r]
set pwd [open "$env(HOME)\\AppData\\Roaming\\basicfile\\PWD.txt" r]
set numtries [expr 3.0]
proc log {} {
if {$::numtries > 0.0} {
if {[.e get] == [read $::usr]} {
if {[.e1 get] == [read $::pwd]} {
close $::usr
close $::pwd
pack forget .l
pack forget .e
pack forget .l1
pack forget .e1
pack forget .b
.l configure -text "Login Successful!"
pack .l
} else {
set ::numtries [expr $::numtries - 1.0]
if {$::numtries <= 0.0} {
.b configure -state disabled
}
}
} else {
set ::numtries [expr $::numtries - 1.0]
if {$::numtries <= 0.0} {
.b configure -state disabled
}
}
} else {
.b configure -state disabled
}
if {$::numtries <= 0.0} {
.b configure -state disabled
}
}
ttk::label .l -text "Enter your name:"
ttk::entry .e
ttk::label .l1 -text "Enter your password:"
ttk::entry .e1 -show "*"
ttk::button .b -text "Login" -command log
pack .l
pack .e
pack .l1
pack .e1
pack .b
This program opens a folder, basicfile, located in the AppData folder of Windows. When it runs, the application works fine, except for one thing. The line that seems to be erroneous is set numtries [expr 3.0]. The program is made so that if the username and password are incorrect it subtracts from this variable, and if the variable reaches 0, the button is disabled. However, when I run the program and press the button three times with an incorrect username and password in the input boxes, it goes to the line .l configure -text "Login Successful!" and bypasses the login part. My question is, why does it disregard the login code and still go in? I should also mention the fact that if I change the line set numtries [expr 3.0] to set numtries [expr 2.0], the program works fine. Thanks!

Answer 1

The problem could possibly be this. The read command reads the whole file at once, so the next time you read from the files you get empty strings. If your name and password fields are empty, they will be equal to the empty strings read from your files, and the login will be successful.
Something like this ought to work:
set dir $env(HOME)/AppData/Roaming/basicfile
set uf [open [file join $dir USR.txt]]
set pf [open [file join $dir PWD.txt]]
set usr [read -nonewline $uf]
set pwd [read -nonewline $pf]
close $uf
close $pf
set numtries 3
ttk::label .nl -text "Enter your name:"
ttk::entry .ne
ttk::label .pl -text "Enter your password:"
ttk::entry .pe -show "*"
ttk::button .b -text "Login" -command log
pack {*}[winfo children .]
proc log {} {
global numtries usr pwd
if {[incr numtries -1] > 0} {
if {([.ne get] eq $usr) && ([.pe get] eq $pwd)} {
destroy {*}[winfo children .]
ttk::label .l -text "Login successful"
pack .l
} else {
.ne delete 0 end
.pe delete 0 end
}
} else {
destroy {*}[winfo children .]
ttk::label .l -text "Too many tries"
pack .l
}
}
If you have an older, obsolete version of Tcl, pack {*}[winfo children .] and the eq operator won't work: try eval pack [winfo children .] (likewise with destroy) and == instead. Or better yet, upgrade.
Documentation: close, destroy, file, global, if, incr, open, pack, proc, read, set, ttk::button, ttk::entry, ttk::label, winfo

Answer 2

Your program seems to be incomplete. Anyway, try this (update the path of usr.txt and pwd.txt):
package require Tk
set usr [open "usr.txt" r]
set pwd [open "pwd.txt" r]
set numtries 3
proc log {} {
puts "Attempt # $::numtries"
if {$::numtries <= 0} {
close $::usr
close $::pwd
.l configure -text "Max retries exceeded..."
.b configure -state disabled
pack forget .e
pack forget .e1
return
}
if {([.e get] != [gets $::usr]) || \
([.e1 get] != [gets $::pwd])} {
incr ::numtries -1
return
}
.l configure -text "Login Successful!"
pack forget .e
pack forget .e1
pack forget .b
close $::usr
close $::pwd
}
ttk::label .l -text "Enter your name:"
pack .l
ttk::entry .e
ttk::entry .e1
pack .e
pack .e1
button .b -text submit -command log
.b configure -state active
pack .b