Why can't I load this previously serialized object? - actionscript-3

Question

This class is serializable:
package com.things {
public class MySerializableObject {
public var intVals:Array;
public var numVals:Array;
public var stringVals:Array
public function MySerializableObject() {
}
public function init(ints:Vector.<int>, nums:Vector.<Number>, strings:Vector.<String>) {
intVals = new Array();
for each (var i:int in ints) {
intVals.push(i);
}
numVals = new Array();
for each (var n:Number in nums) {
numVals.push(n);
}
stringVals = new Array();
for each (var s:String in strings) {
stringVals.push(s);
}
}
}
}
We can do this:
registerClassAlias("com.things.MySerializableObject", MySerializableObject);
And then do this:
var sharedObject:SharedObject = SharedObject.getLocal(SAVE_NAME); //SAVE_NAME is a string constant
var mso:MySerializableObject = getInitializedMSO();
sharedObject.data.mso = mso;
sharedObject.flush();
var newMSO:MySerializableObject = sharedObject.data.mso as MySerializableObject;
trace(newMSO); //outputs "[Object MySerializableObject]"
However, if we restart the application and do this:
var sharedObject:SharedObject = SharedObject.getLocal(SAVE_NAME);
registerClassAlias("com.things.MySerializableObject", MySerializableObject);
var previouslySavedMSO:MySerializableObject = sharedObject.data.mso as MySerializableObject;
trace(previouslySavedMSO); //outputs "null"
Flash apparently fails to read the saved object as a MySerializableObject after we close and re-open the application. We can see, by inspecting the SO in a debugger, that the data is still there, but Flash can't typecast it back into its original data type anymore. Is this the expected behavior? If not, what is the problem and how can we fix it?

Answer 1

You have to register your class aliases before you read from your LSO (or byte stream, etc..) otherwise you will end up with an anonymous object. Since you are than casting via an as the result will be null.
Returns null on second run:
var sharedObject:SharedObject = SharedObject.getLocal(SAVE_NAME);
registerClassAlias("com.things.MySerializableObject", MySerializableObject);
if (sharedObject.size > 0) {
var newMSO:MySerializableObject = sharedObject.data.mso as MySerializableObject;
trace(newMSO);
} else {
sharedObject.data.mso = getInitializedMSO();
sharedObject.flush();
trace(sharedObject.data.mso);
}
Returns MySerializableObject on the second run:
registerClassAlias("com.things.MySerializableObject", MySerializableObject);
var sharedObject:SharedObject = SharedObject.getLocal(SAVE_NAME);
if (sharedObject.size > 0) {
var newMSO:MySerializableObject = sharedObject.data.mso as MySerializableObject;
trace(newMSO);
} else {
sharedObject.data.mso = getInitializedMSO();
sharedObject.flush();
trace(sharedObject.data.mso);
}
Cut/Paste Example:
package {
import flash.display.Sprite;
import flash.net.SharedObject;
import flash.net.registerClassAlias;
public class Main extends Sprite {
private const SAVE_NAME:String = "foobar";
public function Main() {
registerClassAlias("com.things.MySerializableObject", MySerializableObject);
var sharedObject:SharedObject = SharedObject.getLocal(SAVE_NAME);
if (sharedObject.size > 0) {
var newMSO:MySerializableObject = sharedObject.data.mso as MySerializableObject;
trace(newMSO);
} else {
sharedObject.data.mso = getInitializedMSO();
sharedObject.flush();
trace(sharedObject.data.mso);
}
}
public function getInitializedMSO():MySerializableObject {
return new MySerializableObject();
}
}
}
class MySerializableObject {
public var intVals:Array;
public var numVals:Array;
public var stringVals:Array
public function MySerializableObject() {
}
public function init(ints:Vector.<int>, nums:Vector.<Number>, strings:Vector.<String>) {
intVals = new Array();
for each (var i:int in ints) {
intVals.push(i);
}
numVals = new Array();
for each (var n:Number in nums) {
numVals.push(n);
}
stringVals = new Array();
for each (var s:String in strings) {
stringVals.push(s);
}
}
}