Access 2010 VBA on KeyPress Pause for seconds before initiating - ms-access

Question

I'm creating an auto-filter feature in Access 2010 Forms using VBA.
My goal is to do the following:
If the user presses an Enter key - do a search
If user presses any letter character key or number key then do the following
Check to make sure the length of the search string is greater than 3 characters.
If the first condition is fulfilled is true then WAIT 0.5 seconds
After 0.5 seconds if the length of the new search text is equal to the old then call a search (the program will assume the user stopped typing and is waiting for a result)
I'm thinking my problem is that I'm trying to execute all of this in the _KeyPress event.
Private Sub search_txt_KeyPress(KeyAscii As Integer)
Dim txt As String, stxt As String
txt = Me.search_txt.Text
'If the enter key is pressed, then search
If (KeyAscii = vbKeyReturn) Then
stxt = "*" & txt & "*"
Call Module2.searchJobs(stxt, 0)
Else
End If
'If the key pressed is a letter character or number
If (KeyAscii >= 48) Then
'If the search value is greater than 3 characters
If (Len(txt) > 3) Then
'Pause for 3 seconds
Call Pause(0.5)
'If the string lengths are still equal to each other then search
If (Len(txt) = Len(Me.search_txt.Text)) Then
stxt = "*" & txt & "*"
Call Module2.searchJobs(stxt, 0)
Else
End If
Else
End If
Else
End If
End Sub
Here's my Pause Function
Public Function Pause(NumberOfSeconds As Variant)
On Error GoTo Err_Pause
Dim PauseTime As Variant, start As Variant
PauseTime = NumberOfSeconds
start = Timer
Do While Timer < start + PauseTime
DoEvents
Loop
Exit_Pause:
Exit Function
Err_Pause:
MsgBox err.Number & " - " & err.DESCRIPTION, vbCritical, "Pause()"
Resume Exit_Pause
End Function

Answer 1

VBA is not "multi-threading". So, when you call your Pause() function, it doesn't do anything and any action the user do (including key press) are void, so the approach is not correct.
Instead of using a Pause() function, use the timer of your form:
You should enable the timer instead of calling a Pause() function, and move your check-length logic in the timer event. When you're entering the timer event, you disable the timer.
Something like this :
' Add Load event to the form
Private Sub Form_Load()
Me.TimerInterval = 0 ' disable timer
End Sub
' Add Ontimer event to the form
Private Sub Form_Timer()
Dim txt As String, stxt As String
Me.TimerInterval = 0 ' disable timer
txt = Me.search_txt.Text
'If the string lengths are still equal to each other then search
If (Len(txt) = Len(Me.search_txt.Text)) Then
stxt = "*" & txt & "*"
Call Module2.searchJobs(stxt, 0)
Else
End If
End Sub
Private Sub search_txt_KeyDown(KeyAscii As Integer, Shift As Integer)
Dim txt As String, stxt As String
txt = Me.search_txt.Text
'If the enter key is pressed, then search
If (KeyAscii = vbKeyReturn) Then
stxt = "*" & txt & "*"
Call Module2.searchJobs(stxt, 0)
Else
End If
'If the key pressed is a letter character or number
If (KeyAscii >= 48) Then
'If the search value is greater than 3 characters
If (Len(txt) > 3) Then
' enable timer to 0.5 second
Form.TimerInterval = 500 'milliseconds
Else
End If
Else
End If
End Sub
Additionally, take care to this:
When you enter the KeyDown event, your search_txt.Text will not contain yet the last letter pressed by the user.