Continuous object rotation around point - actionscript-3

Question

I want to make a function similar to rotateAroundInternalPoint(). So far my solution is this:
import flash.events.Event;
import flash.geom.Matrix;
import flash.geom.Point;
addEventListener( Event.ENTER_FRAME, onFrame );
function onFrame(e:Event):void
{
var m:Matrix = item.transform.matrix.clone();
var point:Point = new Point( 50, 50 ); // The object's width and height are 100px, so 50 is the center
point = m.transformPoint( point );
m.translate( -point.x, -point.y );
m.rotate( 5 * ( Math.PI / 180 ) );
m.translate( point.x, point.y );
item.transform.matrix = m;
}
However there is a fundamental flaw in this code - it gets less and less precise with each iteration.
Could somebody point out what's causing this and what the solution would be?

Answer 1

I've solved the problem with introducing a reference matrix that would not change, so the mistake from the initial iteration would be non-existent.
Here's the implementation:
import flash.events.Event;
import flash.geom.Matrix;
import flash.geom.Point;
var referenceMatrix:Matrix = item.transform.matrix.clone();
addEventListener( Event.ENTER_FRAME, onFrame );
var i:Number = 0; // you'll need this because the referenceMatrix rotation will only go one step, so instead you need to increase the rotation
function onFrame(e:Event):void
{
var m:Matrix = referenceMatrix.clone();
var point:Point = new Point( 100, 100 ); // pivot point local to the object's coordinates
point = m.transformPoint( point );
m.translate( -point.x, -point.y );
m.rotate( i * ( Math.PI / 180 ) );
m.translate( point.x, point.y );
item.transform.matrix = m;
i += 1.2; // rotation step
}
Please note that this code is written in a frame and isn't well-optimized for real use, rather it illustrates the algorithm.