AS3 Increment Timer by User Input - actionscript-3

Question

I am a noob to AS3 so excuse me, please.
I have a timer on my app that I am trying to use as a stop watch, What I would like to do is start it at a specified time not always at 0?
I would like the user to enter in a text box a value of 1 to 99 and the timer starts from there entered value.
Thanks in advance.
import flash.utils.Timer;
import flash.events.TimerEvent;
import flash.events.MouseEvent;
var customtime:int;
clock.text = "00:00";
var myTimer:Timer = new Timer(1000,0);
myTimer.addEventListener(TimerEvent.TIMER, stopwatch);
function stopwatch(event:TimerEvent):void
{
clock.text = convert_time(myTimer.currentCount);
}
start_btn.addEventListener(MouseEvent.CLICK, startClock);
stop_btn.addEventListener(MouseEvent.CLICK, stopClock);
reset_btn.addEventListener(MouseEvent.CLICK, resetClock);
setTime_btn.addEventListener(MouseEvent.CLICK, setCustomTime);
function startClock(evt:MouseEvent):void
{
myTimer.start();
}
function stopClock(evt:MouseEvent):void
{
myTimer.stop();
}
function resetClock(evt:MouseEvent):void
{
myTimer.reset();
clock.text = "00:00";
}
function setCustomTime(evt:MouseEvent)
{
var t1:int = int(setTimeTxt.text)*60;
clock.text = convert_time(t1);
customtime = t1;
}
function time_update(t1:int):int
{
var t2:int=t1*60;
return t2;
}
function convert_time(currentAmountSecs:int):String
{
var minutes:int = Math.floor(currentAmountSecs / 60);
var seconds:int = currentAmountSecs % 60;
var prependString:String = "";
if ( minutes < 10 )
{
prependString = "0";
}
var prependStringsec:String = "";
if ( seconds < 10 )
{
prependStringsec = "0";
}
return prependString + minutes + ":" + prependStringsec + seconds;
}

Answer 1

Well you can't change Timer/currentCount but you can store a start count and display startCount + myTimer.currentCount:
var startCount:int = 100;
clock.text = convert_time(startCount + myTimer.currentCount);
As for how to determine the startCount from a user text input: you can use parseInt to convert text to an integer. You should also restrict the text input to numbers, and you can enforce a range of 0-99 using Math.min and Math.max:
// restrict input characters to numbers
input.restrict = "0-9";
// update the `startCount` any time user input changes
input.addEventListener(Event.CHANGE, inputChange);
function inputChange(e:Event):void {
// parse an integer from the text input
startCount = parseInt(input.text);
// limit the range to 0-99
startCount = Math.max(0, Math.min(startCount, 99));
// make sure the input text displays the in-range value
if (input.text != String(startCount))
input.text = String(startCount);
}