Ping output to csv via batch - csv

Question

I got most of the following batch file from this site and have modified it for my needs:
#echo off
set/p host=host Address:
set logfile=Log_%host%.log
set csfile=pings_%host%.csv
echo Target Host = %host% >%logfile%
netsh interface show interface >>%logfile%
nslookup myip.opendns.com resolver1.opendns.com >>%logfile%
for /f "tokens=*" %%A in ('ping %host% -n 1 ') do (echo %%A>>%logfile% && GOTO Ping)
:Ping
for /f "tokens=* skip=2" %%A in ('ping %host% -n 1 ') do (
echo %date% %time:~0,2%:%time:~3,2%:%time:~6,2% %%A>>%logfile%
echo %date%,%time:~0,2%:%time:~3,2%:%time:~6,2%,%%A>>%csfile%
echo %date% %time:~0,2%:%time:~3,2%:%time:~6,2% %%A
timeout 1 >NUL
GOTO Ping)
The output to the .log file is exactly how I want it. The csv file output looks like this:
02/16/2016 Tue, 8:02:03,Reply from 173.194.115.33: bytes=32 time=16ms TTL=56
I would like to see something like this at the very least:
02/16/2016 Tue, 8:02:03,Reply from 173.194.115.33:, bytes=32, time=16ms, TTL=56
Optimally, I'd like the csv to look like this:
Date,Time,IP,Bytes,Time,TTL
02/16/2016 Tue,8:02:03,173.194.115.33,32,16ms,56
02/16/2016 Tue,8:02:04,173.194.115.33,32,17ms,56
...
I'd like to stay away from PowerShell if possible.
Thanks,
Joe

Answer 1

#ECHO OFF
SETLOCAL
SET "destdir=U:\destdir"
set "host=google.com"
set "csfile=%destdir%\pings_%host%.csv"
set "flagfile=%destdir%\flagfile.flg"
:: Ensure flagfile exists
ECHO.>"%flagfile%"
ECHO(Date,Time,IP,Bytes,Time,TTL>"%csfile%"
:PING
IF NOT EXIST "%flagfile%" GOTO :EOF
for /f "tokens=* skip=2" %%A in ('ping %host% -n 1 ') do (
FOR /f "tokens=1,4,6,8,10delims=:= " %%P IN ("%time:~0,2% %%A") DO (
echo %date%,%%P:%time:~3,2%:%time:~6,2%,%%Q,%%R,%%S,%%T>>%csfile%
)
echo %date% %time:~0,2%:%time:~3,2%:%time:~6,2% %%A
timeout 1 >NUL
GOTO Ping)
GOTO :EOF
Since you have the logfile processing already sorted, this would generate the csvfile. I've set up filenames suit my system and pinged Google for convenience.
This processes the line
" 8 Reply from 173.194.115.33:, bytes=32, time=16ms, TTL=56"
Assuming "reply from" (no doubt that could be gated if required) usng separators of :=and Space It's then simply a matter of outputting the date data followed by the first token, the minutes and seconds with punctuation and a comma-separated list of the remaining required tokens.
I've added a flagfile which gets created on the first entry. If you delete the flagfile, the batch stops, so you don't have to CtrlC to kill the process.

Answer 2

You can use a FOR loop to parse out only the values you care about.
FOR /F "usebackq tokens=1-10 delims==:< " %%A IN (`ping google.com -n 1`) DO (
REM Only process the response line.
IF "%%A"=="Reply" (
ECHO %%C,%%E,%%G,%%I
)
)
This snippet puts the the following data into CSV format:
IP, bytes, time, TTL
Sample output:
74.125.138.138,32,11ms,43
You should be able to adapt this to your script fairly easily.