Embed HTML email attatchment in body from access query - html

Question

I have a database. It has a form that sends an email, attaching query results to it (the attachment is an HTML document).
My VBA code for the form is:
Private Sub button_send_Click()
DoCmd.SendObject acSendQuery, Me!query_name, acFormatTXT, me!email_address, , , "Subject Line"
End Sub
I would not like my form to attach the query results. I need it to put the content from the attachment into the main body of the email instead.
Is there a way of doing this with VBA?

Answer 1

Use a function like this to list the output:
Public Function ListQuery() As String
Dim qdy As DAO.QueryDef
Dim rst As DAO.Recordset
Dim fld As DAO.Field
Dim List As String
Set qdy = CurrentDb.QueryDefs("YourQueryName")
qdy.Parameters(0).Value = Forms!NameOfYourForm!NameOfSomeTextbox.Value
qdy.Parameters(1).Value = Forms!NameOfYourForm!NameOfOtherTextbox.Value
Set rst = qdy.OpenRecordset()
If rst.RecordCount > 0 Then
While Not rst.EOF
For Each fld In rst.Fields
List = List & fld.Value & vbTab
Next
List = List & vbCrLf
rst.MoveNext
Wend
End If
rst.Close
Set fld = Nothing
Set rst = Nothing
Set qdy = Nothing
ListQuery = List
End Function
Then:
Dim MessageText As String
MessageText = ListQuery
DoCmd.SendObject acSendNoObject, , acFormatTXT, Me!email_address, , , "Subject Line", MessageText