I am having trouble with hit detection - actionscript-3

Question

I am having trouble with getting my hit detection to work in as3. I am making a flappy bird like game and when the player dies and goes back to frame 2, we get error #1009. I am new to this so if you could make this as simple as possible it would be much appreciated.Thank you! Here is my code.
import flash.events.Event;
stage.addEventListener(MouseEvent.CLICK, fl_MouseClickHandler);
function fl_MouseClickHandler(event:MouseEvent):void
{
player.y += -100;
}
var randomX:Number = Math.random() * 550;
player.x = 50;
player.y = 50;
var speed:Number = 5;
player.addEventListener(Event.ENTER_FRAME, moveDown);
function moveDown(e:Event):void {
e.target.y += speed;
if(e.target.y >= 400) {
{
gotoAndStop(2);
player.removeEventListener(Event.ENTER_FRAME, moveDown);
}
}
}
var gravity = 8;
stage.addEventListener(Event.ENTER_FRAME, movewt);
function movewt(e:Event):void
{
wt.x = wt.x - 5;
}
stage.addEventListener( Event.ENTER_FRAME, handleCollision)
function handleCollision( e:Event ):void
{
if(player.hitTestObject(wt))
{
gotoAndStop(2);
stage.removeEventListener(MouseEvent.CLICK, fl_MouseClickHandler);
player.removeEventListener(Event.ENTER_FRAME, moveDown);
stage.removeEventListener(Event.ENTER_FRAME, movewt);
stage.removeEventListener( Event.ENTER_FRAME, handleCollision);
}
}

Answer 1

Problem
When this code goes to frame 2
if(e.target.y >= 400)
{
{
gotoAndStop(2);
player.removeEventListener(Event.ENTER_FRAME, moveDown);
}
}
it only removes the ENTER_FRAME event listener from player, all other handlers persist, namely:
fl_MouseClickHandler
movewt
handleCollision
The latter two are executed on their own, which makes them the problematic ones, because the objects that they access are not necessarily present on frame 2.
movewt accesses wt, handleCollision accesses both player and wt. If either player or wt does not exist on frame 2, they are null.
Solution
Don't use frames! While it appears to be very easy to build navigations based on frames, you quickly run into problems like the one at hand. Frames were made for animations and they are great at doing that, so use them for that. How to not use frames is beyond the scope of this answer, there are many resources on the web on how to do that. Most game frameworks don't even have frames and use state machines for that purpose. It's highly recommended to take a look at how game frameworks handle this.
Another problem is the inconsistent way you switch between frames. Sometimes you remove one event listener, sometimes you remove some others...did you just forget to remove all of them? Why do you have this duplicated logic in the first place? If you have different states of your game (say for example, the game itself, which is currently on frame 1 (or whatever frame the code you posted is on) and some game over screen at frame 2), then you should have a clearly defined way to transition between the two states.
If you want to go to the game over state, have one function that does this and do all the cleanup in that function:
function gameOver():void
{
gotoAndStop(2);
stage.removeEventListener(MouseEvent.CLICK, fl_MouseClickHandler);
player.removeEventListener(Event.ENTER_FRAME, moveDown);
stage.removeEventListener(Event.ENTER_FRAME, movewt);
stage.removeEventListener( Event.ENTER_FRAME, handleCollision);
}
Now, whenever you want to change to that state, be it because if the end of the level or because of a collision, call that function:
import flash.events.Event;
var speed:Number = 5;
var gravity = 8;
var randomX:Number = Math.random() * 550;
player.x = 50;
player.y = 50;
stage.addEventListener(Event.ENTER_FRAME, movewt);
stage.addEventListener( Event.ENTER_FRAME, handleCollision);
player.addEventListener(Event.ENTER_FRAME, moveDown);
stage.addEventListener(MouseEvent.CLICK, fl_MouseClickHandler);
function fl_MouseClickHandler(event:MouseEvent):void
{
player.y += -100;
}
function moveDown(e:Event):void
{
e.target.y += speed;
if(e.target.y >= 400)
{
gameOver();
}
}
function movewt(e:Event):void
{
wt.x = wt.x - 5;
}
function handleCollision(e:Event):void
{
if(player.hitTestObject(wt))
{
gameOver();
}
}
function gameOver():void
{
gotoAndStop(2);
stage.removeEventListener(MouseEvent.CLICK, fl_MouseClickHandler);
player.removeEventListener(Event.ENTER_FRAME, moveDown);
stage.removeEventListener(Event.ENTER_FRAME, movewt);
stage.removeEventListener( Event.ENTER_FRAME, handleCollision);
}
Again, ideally you'd use a framework that provides classes that represent game states. This allows for clearly defined transitions between states:
As the code stands now, you have to remember that gameOver() should be called in order to make a proper transition to the game over state and you could still do it in another way. With a library, there's no "other way", only one. But for now, gameOver() will do and should solve your problem.