AS3: New instances of my symbol are overwriting properties of previous instances - actionscript-3

Question

So Im working on a project in Flash and I'm having a very strange issue.
The second frame in my project has a series of Actions on it that create multiple copies of a symbol which I've named MessageAction in an array of MessageActions. For some reason, if I create multiple MessageActions, all of the MessageActions on the stage will take on the properties of the most recently made MessageAction, and will act as duplicates of that instance so that anything I do to that instance will also be done to them as well. Specifically I have an OnClick event which "selects" the Message Action, and no matter which one I click, all of them will become selected because they are all mirroring the final one I made.
The code I'm using to create the MessageActions is:
var ActionArray:Array = new Array();
ActionArray[0] = new MessageAction(0);
addChild(ActionArray[0]);
ActionArray[0].x = 73;
ActionArray[0].y = 565;
ActionArray[1] = new MessageAction(1);
addChild(ActionArray[1]);
ActionArray[1].x = 73;
ActionArray[1].y = 615;
ActionArray[2] = new MessageAction(2);
addChild(ActionArray[2]);
ActionArray[2].x = 73;
ActionArray[2].y = 665;
ActionArray[3] = new MessageAction(3);
addChild(ActionArray[3]);
ActionArray[3].x = 533;
ActionArray[3].y = 565;
ActionArray[4] = new MessageAction(4);
addChild(ActionArray[4]);
ActionArray[4].x = 533;
ActionArray[4].y = 615;
ActionArray[5] = new MessageAction(5);
addChild(ActionArray[5]);
ActionArray[5].x = 533;
ActionArray[5].y = 665;
And the Symbol's code is as follows:
package {
import flash.display.MovieClip;
import flash.events.MouseEvent;
import flash.events.Event;
public class MessageAction extends MovieClip {
//Message Action Values Key:
// 0- Research
// 1- Email Manager
// 2- Get pricing from vendor
// 3- Get pricing from distributor
// 4- Get pricing from partner page
// 5- Quote customer
public static var ActionType: int = -1;
public static var ActionName: Array = new Array("Research", "Email Manager", "Get pricing from vendor", "Get pricing from distributor", "Get pricing from partner page", "Quote Customer");
public static var Selected:Boolean = false;
public static var IsActive:Boolean = true;
public function MessageAction( MyType:int ) {
ActionType = MyType;
this.addEventListener(Event.ENTER_FRAME, onUpdate);
this.addEventListener(MouseEvent.CLICK, clickHandler);
}
public function setType(MyType: int): void {
ActionType = MyType;
}
public function Activate(): void {
IsActive = true;
}
public function Deactivate(): void {
IsActive = false;
}
function clickHandler(me: MouseEvent): void {
if(IsActive == true){
if (Selected == false) {
Selected = true;
} else {
Selected = false;
}
}
}
function onUpdate(e: Event): void {
if (IsActive == true && ActionType != -1) {
alpha = 1;
ActionText.text = ActionName[ActionType];
} else {
ActionText.text = "---";
alpha = .5;
}
if (Selected == false) {
gotoAndStop(1);
} else {
gotoAndStop(2);
}
}
}
}
Any help would be greatly appreciated. Thank you.

Answer 1

Your use of "static" means that the variable is held at the class level, and every instance will share it. Change it in one, and it changes for all. For example, setting Selected to true for one has the effect of setting Selected to true for ALL instances. If you want each instance to behave differently, just remove the "static" keyword. This will cause the variables to be scoped to their own instances.
instead of...
public static var ActionType: int = -1;
public static var ActionName: Array = new Array("Research", "Email Manager", "Get pricing from vendor", "Get pricing from distributor", "Get pricing from partner page", "Quote Customer");
public static var Selected:Boolean = false;
public static var IsActive:Boolean = true;
...try...
public var ActionType: int = -1;
public static var ActionName: Array = new Array("Research", "Email Manager", "Get pricing from vendor", "Get pricing from distributor", "Get pricing from partner page", "Quote Customer");
public var Selected:Boolean = false;
public var IsActive:Boolean = true;