AS3 NetConnection object must be connected - actionscript-3

Question

I'm beginner in AS3 and making a prototype for a game, I tried to add a video in it and came across this problem.
ArgumentError: Error #2126: NetConnection object must be connected.
at flash.net::NetStream/ctor()
at flash.net::NetStream()
at Main()[/Users/admin/Desktop/Prototype 4/Main.as:27]
at runtime::ContentPlayer/loadInitialContent()
at runtime::ContentPlayer/playRawContent()
at runtime::ContentPlayer/playContent()
at runtime::AppRunner/run()
at ADLAppEntry/run()
at global/runtime::ADLEntry()
I googled it but still don't understand the problem.
This is my code.
package {
import flash.display.*;
import flash.events.*;
import flash.utils.*;
import flash.media.*;
import flash.net.*;
import flash.display.MovieClip;
import flashx.textLayout.events.ModelChange;
public class Main extends Sprite
{
public var mc:Sprite = new Sprite();
public var touch:MovieClip = new Touch();
public var yellowbox:MovieClip = new Yellow();
public var purplebox:MovieClip = new Purple();
public var pinkbox:MovieClip = new Pink();
public var Next:MovieClip = new NEXT();
public var myTimer:Timer = new Timer (2000, 1);
public var vid:Video = new Video(700, 360);
public var nc:NetConnection = new NetConnection();
public var ns:NetStream = new NetStream(nc);
public function Main()
{
// constructor code
addChild(mc);
mc.addChild(yellowbox);
yellowbox.addChild(touch);
touch.y = 1000;
touch.x = 50;
vid.y = 300;
vid.x = 10;
yellowbox.addEventListener (MouseEvent.CLICK, onClick);
myTimer.addEventListener(TimerEvent.TIMER, tick);
nc.connect(null);
vid.attachNetStream(ns);
var listener:Object = new Object();
listener.onMetaData = function(evt:Object):void {};
ns.client = listener;
}
public function onClick (e:MouseEvent):void
{
mc.removeChild(yellowbox);
mc.addChild(purplebox);
purplebox.addChild(vid);
ns.play("rick.mp4");
myTimer.start();
}
function tick(e:TimerEvent):void
{
purplebox.addChild(Next);
Next.y = 1000;
Next.x = 330;
}
}
}
Can someone explain to me what's the problem?
Thanks!

Answer 1

Simply, you can not create a NetStream using a NetConnection which is not connected !
To avoid that error, you should connect your NetConnection and then create your NetStream like this :
var nc:NetConnection,
ns:NetStream;
nc = new NetConnection();
trace(nc.connected); // gives : false
nc.connect(null);
trace(nc.connected) // gives : true
ns = new NetStream(nc);
Hope that can help.