How to split a row into multiple based on a quantity column - ms-access

Question

In MS Access, I have a table like this:
TblA_AutoID SKU Qty Price
1 A3323 2 4.53
2 A3313 1 22.20
3 A3323 3 4.59
I want to create a new table (preferably one that populates automatically as new rows are added to the first table) that splits the first table into 1 row per quantity, like this:
TblB_AutoID TblA_AutoID SKU Price
1 1 A3323 4.53
2 1 A3323 4.53
3 2 A3313 22.20
4 3 A3323 4.59
5 3 A3323 4.59
6 3 A3323 4.59
I work on a couple machines, one with Access 2007, one with Access 2013. I'm guessing this needs to be done in VBA, but if there's a simpler way, that's preferable.

Answer 1

Since all you want at this time is to add Qty number of rows into TableB from each row of TableA, you can load each table into a separate DAO.Recordset and use the data in the TableA recordset to drive additions to the other recordset.
I tested this code with your sample data in Access 2010. It populates TableB as you requested.
Dim db As DAO.Database
Dim rsA As DAO.Recordset
Dim rsB As DAO.Recordset
Dim lngQuantity As Long
Dim i As Long
Set db = CurrentDb
Set rsA = db.OpenRecordset("TableA", dbOpenSnapshot)
Set rsB = db.OpenRecordset("TableB", dbOpenTable, dbAppendOnly)
With rsA
Do While Not .EOF
lngQuantity = !Qty.Value
For i = 1 To lngQuantity
rsB.AddNew
rsB!TblA_AutoID.Value = !TblA_AutoID.Value
rsB!SKU.Value = !SKU.Value
rsB!Price.Value = !Price.Value
rsB.Update
Next ' i
.MoveNext
Loop
End With
rsB.Close
rsA.Close
That part is fairly simple. However, you indicated in a comment that ultimately you intend to synchronize TableB with subsequent changes (updates and deletions) of the data in TableA. Those reconciliation efforts will be much more challenging.