getting exit code of an executed sipp with tcl - tcl

Question

I'm trying to get the exit code " echo $? " after executing SIPp command with exec from tcl :
if { [catch { exec /usr/local/sipp-3.3.990/sipp -t "u1" -s $SERVICE \
-ap $PASSWORD \
-sf $SCRIPT_PATH1 \
-i $LOCAL_IP \
-m 1 -key path $str \
-key dnid *20 \
-timeout 10s\
-trace_err -trace_screen $CLIENT2 -nd | /bin/sh $str/return_code.sh } fid option] }
I have tried to do execute "echo $?" but that didn’t work so I tried to execute it from an other script called "return_code.sh"
#!/bin/sh
echo "exit code: $?"
echo "PPID: $PPID"
but this also didn't work the result is always 0 , any idea about how to get the exit code from tcl ?
Best regards ,

Answer 1

An exhaustive example is given at http://wiki.tcl.tk/1039#pagetoce3a5e27b
This might be easier
set status [catch {sipp ...} output option]
if {$status == 0} {
# sipp did not emit anything to stderr, and exited with status 0
} else {
# some error
set err_info [lassign [dict get $option -errorcode] err_type]
switch -exact -- $err_type {
NONE {
# sipp exited with status 0 but printed something to stderr
# which is captured in $output
}
CHILDSTATUS {
# non-zero exit status
set exit_status [lindex $err_info 1]
set process_id [lindex $err_info 0]
}
default {
puts "some other error: $option"
}
}
}
Ah I see what you're up to now (your supplied code is way too complicated to demonstrate clearly). You're doing sipp .... | sh -c 'echo exit code: $?'. That echo command will always be zero: it is running in a separate process that has not launched any commands. Example:
% set status [catch {exec sh -c {exit 42} | sh -c {echo "previous exit status: $?"}} output option]
1
% puts $output
previous exit status: 0
child process exited abnormally
% set option
-code 1 -level 0 -errorcode {CHILDSTATUS 25539 42} -errorinfo {previous exit status: 0
child process exited abnormally
while executing
"exec sh -c {exit 42} | sh -c {echo "previous exit status: $?"}"} -errorline 1
We see that the 2nd sh process's $? value is zero. However, the pipeline's exit status, as seen by Tcl, is 42.