word alignment in actionscript - actionscript-3

Question

I have a sentence as string.
internal var sentence:string = "Lorem Ipsum is simply dummy text of the printing and typesetting industry.";
Then I was separated every word and stored in an array named wordArray and apply to text field and added to stage using addChild.
for(var i:uint =0;x i< sentence.split(" ").length; i++){
wordArray.push(sentence.split(" ")[i]);
txt = new TextField();
addChild(txt);
txt.text = wordArray[i];
}
Alignement
if(i==0) { txt.x = wordArray[i].x;}
else{ txt.x = wordArray[i -1].width + wordArray[i-1].x+2};
This will align first line perfectly. I want to do with multiline with particular width like TextField.(If word exceeds the boundary limit it has to come to the next line like textField)
?

Answer 1

Firstly, I'll fix you mistakes.
internal var sentence:string
var sentence:String
The default access modifier is internal. You don't need to write internal here.
There is no string class/object in AS3. For strings use String.
for (var i:uint = 0;x i< sentence.split(" ").length; i++){
What is x before i <? Remove it.
In your code the sentence splits multiple times. To avoid this split your sentence once.
var splittedSentence:Array = sentence.split(" ");
for (var i: uint = 0; i < splittedSentence.length; i++)
Next.
wordArray.push(sentence.split(" ")[i]);
txt = new TextField();
addChild(txt);
txt.text = wordArray[i];
You don't need to store a substring in the wordArray. But you should store all TextFields.
txt = new TextField();
addChild(txt);
txt.text = sentence.split(" ")[i];
wordArray.push(txt);
Define variable line which stores current line of the text (from 0).
var line:int = 0;
Set autoSize property to the TextField:
txt.autoSize = TextFieldAutoSize.LEFT;
So the width and the height of the TextField will be resized after the text will be added to the TextField.
if (txt.x + txt.width > stage.stageWidth)
{
txt.x = 0;
line++;
}
If the current TextField is out of bounds, it will be moved to the next line.
Finally, set up y property of the TextField:
txt.y = txt.height * line;
Full code:
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
var sentence: String = "Lorem Ipsum is simply dummy text of the printing and typesetting industry.";
var wordArray: Array = [];
var txt: TextField;
var line:int = 0;
var splittedSentence:Array = sentence.split(" ");
for (var i: uint = 0; i < splittedSentence.length; i++)
{
txt = new TextField();
txt.autoSize = TextFieldAutoSize.LEFT;
addChild(txt);
txt.text = splittedSentence[i];
wordArray.push(txt);
if (i == 0)
txt.x = wordArray[i].x;
else
txt.x = wordArray[i - 1].width + wordArray[i - 1].x + 2;
if (txt.x + txt.width > stage.stageWidth)
{
txt.x = 0;
line++;
}
txt.y = txt.height * line;
}
The result:

Answer 2

I'd say use a multilined TextField with a center-aligned format.
var sentence:String="Lorem Ipsum is simply dummy text of the printing and typesetting industry.";
var altered:String=sentence.split(" ").join("\n");
var ta:TextField=new TextField();
ta.multiline=true; // makes a text area out of a text field, necessary
var tf:TextFormat=new TextFormat("Arial",12); // whatever
tf.align=TextFormatAlign.CENTER; // necessary
ta.defaultTextFormat=tf;
ta.text=altered;
addChild(ta);
// now we can get proper text height and actually do whatever we wish.
And if you are missing word wrap functionality, you should not use altered but use original sentence, and set ta.wordWrap=true;.