Batch echo string is capped when passed as argument - csv

Question

I run the batch script on below on a csv file.
#echo off
set "filename=test.csv"
for /f "USEBACKQtokens=*" %%A in ("%filename%") do (
call :myecho "%%A"
)
pause
:myecho
echo %1
GOTO :eof
A typical line in the csv file looks like this:
Text and some more 2/11/2015,A234,Mr. Example Guy,18217.01,"$20,729.89","$4,111.06","$4,453.08"
The echo will actually result in the following output:
Text and some more 2/11/2015,A234,Mr. Example Guy,18217.01,"$20,
Somehow it cuts off at the comma, after the first quotation mark. I don't understand why. Could someone explain, and tell me how I could print the entire line there? Note that if I print directly in the for loop it prints the entire line.

Answer 1

The following line
call :myecho "%%A"
is expanded to
call :myecho "Text and some more 2/11/2015,A234,Mr. Example Guy,18217.01,"$20,729.89","$4,111.06","$4,453.08""
Arguments to CALLed subroutines are delimited by any of <space>, ,, ;, <tab>, =, or <0x255>. Delimiters within quotes are ignored. The commas in $20,729.89 are quoted in the original CSV, but they are not quoted in your CALL because you added your own enclosing quotes. So argument %1 ends at the first unquoted comma in the dollar amount.
If you want to pass a string containing quotes and delimiters to a subroutine, then you should pass them by reference via an environment variable. You should use delayed expansion to expand the variable so that all characters are protected. But delayed expansion should be off within the FOR loop so that ! values are not corrupted when the FOR loop variable is expanded.
#echo off
setlocal disableDelayedExpansion
set "filename=test.csv"
for /f "USEBACKQtokens=*" %%A in ("%filename%") do (
set "var=%%A"
call :myecho var
)
pause
exit /b
:myecho
setlocal enableDelayedExpansion
echo !%1!
exit /b