Detect duplicates - duplicates

Question

My question regards detecting duplicates. Say I have the following data:
clear all
input str2 pos str10 name
A Joe
A Joe
B Frank
C Mike
C Ted
D Mike
D Mike
E Bill
F Bill
end
If I want to detect all the duplicate names, I would simply type:
duplicates tag name, gen(flag)
This gives me:
pos name flag
A Joe 1
A Joe 1
B Frank 0
C Mike 2
C Ted 0
D Mike 2
D Mike 2
E Bill 1
F Bill 1
That is great - it indicates that Joe, Mike, and Bill are duplicates.
But let's say that I want to not include any duplicates that are duplicates only within pos. In other words, I do not want to find that Joe is duplicate because Joe appears only within pos A. I only want to find that Mike and Bill are duplicates. (While Mike is duplicated within D, he also appears in C, so he appears in more than one pos.)
In other words, I want:
pos name flag
A Joe 0
A Joe 0
B Frank 0
C Mike 1
C Ted 0
D Mike 1
D Mike 1
E Bill 1
F Bill 1
Note that here Mike takes flag of only 1 instead of 2. That is because I am treating Mike in D as appearing only once instead of twice. Having 2 instead of 1 is not problematic if the solution produces this.
Is there a way to do this?

Answer 1

This is no longer a duplicates problem in the specific sense of duplicates. (Disclaimer: I originally wrote it.)
You just want to know if a given name occurs in different groups. That problem is reviewed in various places, such as here.
One way to proceed is to tag each distinct joint occurrence of name and pos just once, and then count over groups.
clear
input str1 pos str5 name flag
A Joe 1
A Joe 1
B Frank 0
C Mike 2
C Ted 0
D Mike 2
D Mike 2
E Bill 1
F Bill 1
end
egen tag = tag(name pos)
egen npos = total(tag), by(name)
list , sepby(pos)
+---------------------------------+
| pos name flag tag npos |
|---------------------------------|
1. | A Joe 1 1 1 |
2. | A Joe 1 0 1 |
|---------------------------------|
3. | B Frank 0 1 1 |
|---------------------------------|
4. | C Mike 2 1 2 |
5. | C Ted 0 1 1 |
|---------------------------------|
6. | D Mike 2 1 2 |
7. | D Mike 2 0 2 |
|---------------------------------|
8. | E Bill 1 1 2 |
|---------------------------------|
9. | F Bill 1 1 2 |
+---------------------------------+
Some may like to see a solution without egen:
bysort name pos: gen tag = _n == 1
by name: gen npos = sum(tag)
by name replace npos = npos[_N]
This could be rewritten using just one new variable:
bysort name pos: gen npos = _n == 1
by name: replace npos = sum(npos)
by name: replace npos = npos[_N]