Calling Sql Server 2008 stored procedure from vb6 with datetime - sql-server-2008

Question

I have a legacy vb6 app which accesses databases running on both SQL2000 and SQL2008 databases.
When calling a stored procedure with a datetime parameter from vb6 using an adDBTimeStamp input parameter, the complete date time, including seconds is passed to the stored procedure.
When calling the same stored procedure in an SQL2008 r2 database, the seconds are always zero.
EDIT:
Create the following stored procedure on both a SQL2000 database and an SQL2008 R2 database.
CREATE PROCEDURE [dbo].[TestDate] (#DateAndTime DATETIME)
AS
SET NOCOUNT ON
BEGIN
SELECT #DateAndTime AS DateAndTime
END
Then build a VB6 app with the following command button event method:
Private Sub Command_Click()
Dim SQL2000_ConnectionString As String
Dim SQL2008_ConnectionString As String
Dim DateOnly As Date
Dim DateAndTime As Date
DateAndTime = DateTime.Now
SQL2000_ConnectionString = "Driver={SQL Server};Server=<SQL2000ServerName>;UID=<UserName>;pwd=<Password>;Database=<DataBaseName>;dsn=''"
SQL2008_ConnectionString = "Provider=SQLNCLI10;DataTypeCompatibility=80;Server=<SQL2008ServerName>;Database=<DataBaseName>;User Id=<UserName>;Password=<Password>;"
Dim conn As ADODB.Connection
Dim cmd As ADODB.Command
Dim rs As ADODB.Recordset
Dim Msg As String
Set conn = New ADODB.Connection
conn.ConnectionTimeout = 300
Call conn.Open(SQL2000_ConnectionString)
Set cmd = New ADODB.Command
With cmd
.CommandType = adCmdStoredProc
Set .ActiveConnection = conn
.CommandType = adCmdStoredProc
.CommandText = "TestDate"
.CommandTimeout = 60
Call .Parameters.Append(.CreateParameter("#dtDateAndTime", adDBTimeStamp, adParamInput))
.Parameters("#dtDateAndTime").Value = DateAndTime
Set rs = .Execute
End With
If Not rs.EOF Then
Msg = "DateTime:" & rs.fields("DateAndTime").Value
Call MsgBox(Msg)
End If
Call conn.Close
Set conn = New ADODB.Connection
conn.ConnectionTimeout = 300
Call conn.Open(SQL2008_ConnectionString)
Set cmd = New ADODB.Command
With cmd
.CommandType = adCmdStoredProc
Set .ActiveConnection = conn
.CommandType = adCmdStoredProc
.CommandText = "TestDate"
.CommandTimeout = 60
Call .Parameters.Append(.CreateParameter("#dtDateAndTime", adDBTimeStamp, adParamInput))
.Parameters("#dtDateAndTime").Value = DateAndTime
Set rs = .Execute
End With
If Not rs.EOF Then
Msg = "DateTime:" & rs.fields("DateAndTime").Value
Call MsgBox(Msg)
End If
Call conn.Close
End Sub
When you execute the vb6 app, the first message box displays with the date and time including seconds. The second message box has the seconds display as zero.
I am seeing the same thing when I log the input parameters within the databases.
It appears as though the call to the SQL2008 R2 database is truncating the seconds of the input parameter.
2nd EDIT:
It appears that the OLE DB driver may be the culprit.
When I change to use the Native Client, it appears to work correctly.
SQL2008_ConnectionString = "Driver={SQL Server Native Client 10.0};Server=<SQL2008ServerName>;UID=<UserName>;pwd=<Password>;Database=<DataBaseName>;"
As this is a heavily used legacy app, and regression testing everything to use a new driver is time prohibitive. Is there any way to make the OLE DB driver do the correct thing?
3rd EDIT:
Just realized it is not a SQL 2008 R2 box. I was mistaken. It is just SQL2008
Here is my ##VERSION:
Microsoft SQL Server 2008 (SP3) - 10.0.5500.0 (X64) Sep 21 2011 22:45:45 Copyright (c) 1988-2008 Microsoft Corporation Enterprise Edition (64-bit) on Windows NT 6.1 <X64> (Build 7601: Service Pack 1) (VM)

Answer 1

I found the solution.
Apparently the solution is to set the precision and numeric scale on the command object parameter to that of the defined size of addbTimeStamp.
Adding these two lines to the cmd object parameter before the call to the SQL2008 database, and the seconds are passed to the stored procedure.
.Parameters("#dtDateAndTime").Precision = 23
.Parameters("#dtDateAndTime").NumericScale = 3