Unload MovieClip and RemoveChild AS3 - actionscript-3

Question

I developed a code that is going to load a movie clip making a comparison with two dynamic text.
If dynamic text is greater than the other one, it will lunch a specific movie clip. I[m trying to develop a light sign system comparing numbers.
Action script is importing data from .txt files (exported using EXCEL and VBA). I created a code to reload all data using a timer. I create that so it's not necessary to reopen the .swf file.
Here is the automatically reload code:
// timer loading
var timer:Timer = new Timer(2500);
timer.addEventListener(TimerEvent.TIMER, onTimer);
timer.start();
Now, the code is being applied to all actions, include an action to redownload the .txt files, here it is:
function onTimer(evt:TimerEvent):void { //primeiro indicador parte
var loader:URLLoader = new URLLoader(new URLRequest("bdaily.txt"));
loader.addEventListener(Event.COMPLETE, completeHandler);
function completeHandler(event:Event):void {
var loadedText:URLLoader = URLLoader(event.target); bdaily.text = loadedText.data;
}
Now, this code is comparing the .txt (dynamic text) and loading or not loading a new movie clip.
var clp_index = parseInt(bdaily.text) >= parseInt(basketdtarget.text) ? 1 : 2
var new_clp = clp_index == 1 ? new clp_01() : new clp_02()
addChild(new_clp)
The PROBLEM IS:
-> Everything is working fine, all data is being loaded and are shown in the dynamic text.
The real thing is that all movie clips are being loaded in an infinite loop due the loop timer set, a lot of ram memory is being consumed. The code is working but its loading movie clips above movie clip.
I need to implement my code and insert a code to erase the movie clips after calling the loop again.

Answer 1

There are a few ways you can accomplish this. I'll show a couple of them.
Make your new_clp var global to the current class or timeline (move it's declaration to the same place as your timer)
var timer:Timer = new Timer(2500);
timer.addEventListener(TimerEvent.TIMER, onTimer);
timer.start();
var new_clp:DisplayObject;
Then, remove it before creating a new clip:
if(new_clp){ //if there is already something in this variable, then remove it
removeChild(new_clp);
}
var clp_index = parseInt(bdaily.text) >= parseInt(basketdtarget.text) ? 1 : 2
new_clp = clp_index == 1 ? new clp_01() : new clp_02()
addChild(new_clp)
Walk the current scopes display list and remove all clp_01 and clp_02 instances:
var i:int = numChildren;
while(i--){
if(getChildAt(i) is clp_01 || getChildAt(i) is clp_02){
removeChild(getChildAt(i));
//if you have any listeners attached to the object, remove them now
}
}
var clp_index = parseInt(bdaily.text) >= parseInt(basketdtarget.text) ? 1 : 2
var new_clp = clp_index == 1 ? new clp_01() : new clp_02()
addChild(new_clp)
Something else to consider for memory management, is if you only have the two clips, just keep them both loaded all the time, and change the visibility of them every timer tick:
var timer:Timer = new Timer(2500);
timer.addEventListener(TimerEvent.TIMER, onTimer);
timer.start();
var clp1:clp_01 = new clp_01;
var clp2:clp_02 = new clp_02;
addChild(clp1);
addChild(clp2);
Then in your other block of code:
var clp_index = parseInt(bdaily.text) >= parseInt(basketdtarget.text) ? 1 : 2
clp1.visible = clp_index == 1;
clp2.visible = clp_index == 2;