As3 Error: Error #1009: Cannot access a property or method of a null object reference - actionscript-3

Question

I seem to be having an error with my inventory system.
This is my class:
package
{
import flash.display.*;
public class InventoryDemo extends MovieClip
{
var inventory:Inventory;
public function InventoryDemo()
{
inventory = new Inventory(this);
inventory.makeInventoryItems([d1,d2]);
}
}
}
I have already placed d1 and d2 objects in a second keyframe.
And this is the child class:
package
{
import flash.display.*;
import flash.events.*;
public class Inventory
{
var itemsInInventory:Array;
var inventorySprite:Sprite;
public function Inventory(parentMC:MovieClip)
{
itemsInInventory = new Array ;
inventorySprite = new Sprite ;
inventorySprite.x = 50;
inventorySprite.y = 360;
parentMC.addChild(inventorySprite);
}
function makeInventoryItems(arrayOfItems:Array)
{
for (var i:int = 0; i < arrayOfItems.length; i++)
{
arrayOfItems[i].addEventListener(MouseEvent.CLICK,getItem);
arrayOfItems[i].buttonMode = true;
}
}
function getItem(e:Event)
{
var item:MovieClip = MovieClip(e.currentTarget);
itemsInInventory.push(item);
inventorySprite.addChild(item);
item.x = itemsInInventory.length - 1 * 40;
item.y = 0;
item.removeEventListener(MouseEvent.CLICK,getItem);
item.addEventListener(MouseEvent.CLICK,useItem);
}
function useItem(e:Event)
{
var item:MovieClip = MovieClip(e.currentTarget);
trace(("Use Item:" + item.name));
}
}
}
The code works when I try it in a black project with only d1 and d2 in the stage. Can any one help me solve this?

Answer 1

Your error suggests that d1 and d2 are not created at the time that you call
inventory.makeInventoryItems([d1,d2]);
You suggest that you have created d1 and d2 in the second keyframe, but if InventoryDemo is your DocumentClass, then it will run before you reach the second keyframe.
So, if you want to use d1 and d2 you either need to move them to the first frame, or you need to not try and use them until the second frame of the Movie has occurred.
If you want to keep d1 and d2 on the second frame, then you need to take the call out of the constructor and into a new function that you call on the second frame:
public function InventoryDemo()
{
//Do nothing here
//inventory = new Inventory(this);
//inventory.makeInventoryItems([d1,d2]);
}
public function initialiseInventory():void
{
//Initialise you inventory here.
inventory = new Inventory(this);
inventory.makeInventoryItems([d1,d2]);
}
Then on the 2nd frame of your timeline call the function:
initialiseInventory();
stop();