writing to a file using puts and calling proc in puts - tcl

Question

I am having a problem in the following code I was trying to write:
set temp [open "check.txt" w+]
puts $temp "hello"
proc print_message {a b} {
puts "$a"
puts "$b"
return 1
}
print_message 3 4
puts "[print_message 5 7]"
puts $temp "[print_message 5 7]"
print_message 8 9
in the puts "[print_message 5 7]" , 5 and 7 are printed on the screen and 1 is printed in the file check.txt. what should i do to print 5 and 7 in the text file and not on the screen.

Answer 1

You can rewrite your proc as follows,
proc print_message {a b { handle stdout } } {
# Using default args in proc. If nothing is passed, then
# 'handle' will have the value of 'stdout'.
puts $handle "$a"
puts $handle "$b"
return 1
}
If any args passed, then it will write into that file handle. Else, it will be on the stdout which is the terminal.
puts "[print_message 5 7 $temp]" ; # This will write into the file
puts "[print_message 5 7]"; # This will write into the stdout

Answer 2

I would write it like puts itself, with the optional channel as the first argument:
proc print_message {args} {
switch [llength $args] {
3 {lassign $args chan a b}
2 {set chan stdout; lassign $args a b}
default {error "wrong # args: should be \"print_message ?channelId? a b\""}
}
puts $chan $a
puts $chan $b
}
print_message 3 4
print_message 5 7
print_message $temp 5 7
print_message 8 9
I'm assuming that you don't actually want to see "1" on stdout.

Answer 3

It's very hard to pin down what you want to do here.
If you want the same printout both on the screen and in the file, you could do it like this:
proc print_message {a b} {
puts $a
puts $b
format %s\n%s\n $a $b
}
puts -nonewline $temp [print_message 5 7]
If you just want to format two values onto one line each, you could do it like this:
proc print_message {a b} {
format %s\n%s\n $a $b
}
puts -nonewline [print_message 5 7] ;# to screen
puts -nonewline $temp [print_message 5 7] ;# to file
Documentation: format, proc, puts