Fibonacci calculator in C, compiled to mips, causes infinite loop - mips

Question

I am trying to translate my fibonacci c code to MIPS assembly code, however, when I run the MIPS code to my MIPS simulator it doesn't seem to end.
C Code:
int fibo(int n)
{
if(n<2) return 1;
else f(n-1)+f(n-2);
}
int main()
{
fibo(5);
}
Assembly Code:
main: addi $sp, $sp, -4
sw $ra, 0($sp)
addi $a0, $zero, 5
jal fibo;
lw $ra, 0($sp)
addi $sp, $sp, 4
fibo: addi $sp, $sp, -12
sw $s0, 0($sp)
sw $s1, 4($sp)
sw $ra, 8($sp)
slti $t0, $a0, 2
beq $t0, $zero, ELSE
addi $v0, $zero, 1
jr $ra
ELSE: addi $s0, $a0, 0
addi $a0, $a0, -1
jal fibo;
addi $s1, $v0, 0
addi $a0, $s0, -2
jal fibo
add $s1, $s1, $v0
j EXIT
EXIT: lw $s0, 0($sp)
lw $s1, 4($sp)
lw $ra, 8($sp)
addi $sp, $sp, 12
jr $ra

Answer 1

A few issues here.
First, your main function was missing its terminating jr $ra, meaning that main fell through into fibo after being executed.
Second, in your if statement, where you return 1, you call jr $ra directly, which means the stack goes unrestored. I swapped this out with a call to j EXIT.
Finally, at the end of your else you add f(n-1) and f(n-2) into $s1. This register should be $v0 as you are intending to return this result.
The fixed up code is as follows:
main:
addi $sp, $sp, -4
sw $ra, 0($sp)
addi $a0, $zero, 5
jal fibo
move $a0 $v0
li $v0 1
syscall
lw $ra, 0($sp)
addi $sp, $sp, 4
jr $ra
fibo:
addi $sp, $sp, -12
sw $s0, 0($sp)
sw $s1, 4($sp)
sw $ra, 8($sp)
slti $t0, $a0, 2
beq $t0, $zero, ELSE
addi $v0, $zero, 1
j EXIT
ELSE:
addi $s0, $a0, 0
addi $a0, $a0, -1
jal fibo
addi $s1, $v0, 0
addi $a0, $s0, -2
jal fibo
add $v0, $s1, $v0
EXIT:
lw $s0, 0($sp)
lw $s1, 4($sp)
lw $ra, 8($sp)
addi $sp, $sp, 12
jr $ra

Answer 2

Here is my code for the same,but it is written in RISC-V
.text
#x5 me n hai
#x7 me output
li x5 7
li x6 2
jal x1 FIB
j EXIT
FIB:
bge x5 x6 REC
addi x7 x5 0
jalr x0 0(x1)
#Handled Base Case
REC:
# Handling Rec. Case
addi sp sp -12
sw x1 0(sp)
sw x5 4(sp)
addi x5 x5 -1
jal x1 FIB
sw x7 8(sp)
lw x5 4(sp)
addi x5 x5 -2
jal x1 FIB
lw x13 8(sp)
add x7 x13 x7
lw x1 0(sp)
addi sp sp 12
jalr x0 0(x1)
EXIT:

Answer 3

In addition to the answer of Konrad (https://stackoverflow.com/a/23185991/3729904), I noticed that there is an error in your algorithm. If n<2 the fib algorithm should return n instead of 1.
This can be fixed changing the line:
addi $v0, $zero, 1
into:
add $v0, $zero, $a0